De structuur van tekstdocumenten

From Apache OpenOffice Wiki
Jump to: navigation, search
Book.png

Een tekstdocument kan in principe vier typen van informatie bevatten:

  • De eigenlijke tekst
  • Sjablonen voor opmaak van tekens, alinea's en pagina's
  • Niet-tekstelementen zoals tabellen, afbeeldingen en teken-objecten
  • Globale instellingen voor het tekstdocument

Dit gedeelte richt zich speciaal op de tekst en de daarbij behorende opties voor opmaak.


Alinea's en gedeelten van alinea's

De kern van een tekstdocument bestaat uit een reeks van alinea's. Deze worden niet benoemd, noch geïndexeerd en er is daarom geen mogelijke manier van directe toegang tot individuele alinea's. De alinea's kunnen echter reeksmatig worden benaderd met behulp van het object Enumeration, beschreven in Introductie voor de API. Dit maakt het mogelijk dat de alinea's kunnen worden bewerkt.

Bij het werken met het object Enumeration, moet echter met één speciaal scenario, rekening worden gehouden: het geeft niet alleen alinea's weer, maar ook tabellen (strikt gesproken is, in Apache OpenOffice Writer, een tabel een speciaal type alinea). Voordat u toegang zoekt tot een weergegeven object, zou u daarom moeten controleren of het weergegeven object de service com.sun.star.text.Paragraph voor alinea's of de service com.sun.star.text.TextTable voor tabellen ondersteunt.

Het volgende voorbeeld gaat, in een lus, door de inhoud van een tekst en gebruikt voor elk item een bericht om de gebruiker te informeren of het betreffende object een alinea of een tabel is.

Dim Doc As Object
Dim Enum As Object
Dim TekstElement As Object
 
' Maak het documentobject   
Doc = ThisComponent
' Maak het object voor de nummering 
Enum = Doc.Text.createEnumeration
' lus door alle tekstelementen
 
While Enum.hasMoreElements
  TekstElement = Enum.nextElement
 
  If TekstElement.supportsService("com.sun.star.text.TextTable") Then
    MsgBox "Het huidige blok bevat een tabel."
  End If
 
  If TekstElement.supportsService("com.sun.star.text.Paragraph") Then
    MsgBox "Het huidige blok bevat een alinea."
  End If
 
Wend

Het voorbeeld maakt een documentobject Doc dat verwijst naar het huidige document van Apache OpenOffice. Met de hulp van Doc maakt het voorbeeld dan een object Enumeration aan dat door de individuele gedeelten van de tekst (alinea's en tabellen) gaat en aan het huidige element het object TekstElement toewijst. Het voorbeeld gebruikt de methode supportsService om te controleren of het TekstElement een alinea of een tabel is.

Alinea's

De service com.sun.star.text.Paragraph geeft toegang tot de inhoud van een alinea. De tekst in de alinea kan worden gevonden en gewijzigd met behulp van de eigenschap String:

Dim Doc As Object
Dim Enum As Object
Dim TekstElement As Object
 
Doc = ThisComponent
Enum = Doc.Text.createEnumeration
 
While Enum.hasMoreElements
  TekstElement = Enum.nextElement
 
  If TekstElement.supportsService("com.sun.star.text.Paragraph") Then
    TekstElement.String = Replace(TekstElement.String, "you", "U") 
    TekstElement.String = Replace(TekstElement.String, "twee", "2")
    TekstElement.String = Replace(TekstElement.String, "vier", "4") 
  End If
 
Wend

Het voorbeeld opent het huidige tekstdocument en gaat daar doorheen met behulp van het object Enumeration. Het gebruikt de eigenschap TekstElement.String in alle alinea's om toegang te krijgen tot de relevante alinea's en vervangt de tekenreeksen you, twee en vier door de tekens U, 2 en 4. De functie Replace, die wordt gebruikt voor de vervangingen, valt niet binnen het standaard-taalkundig bereik van Apache OpenOffice BASIC. Dit is een item van de voorbeeldfunctie, die wordt beschreven in Zoeken en evrvangen.

Documentation note.png VBA : De inhoud van de hier beschreven procedure voor toegang tot de alinea's van een tekst is vergelijkbaar met de opsomming Paragraphs, gebruikt in VBA, die wordt verschaft in de daar beschikbare objecten Range en Document. Waar in VBA de toegang tot de alinea's wordt verkregen via hun nummer (bijvoorbeeld, bij de aanroep Paragraph(1)), zou in Apache OpenOffice BASIC het hiervoor beschreven object Enumeration moeten worden gebruikt.


Er zijn geen identieke objecten in Apache OpenOffice BASIC voor de opsommingen Characters, Sentences en Words zoals die voorkomen in VBA. U heeft echter de optie om over te schakelen naar een TextCursor welke het u mogelijk maakt om te navigeren op het niveau van tekens, zinnen en woorden.

Gedeelten van alinea's

Het vorige voorbeeld kan de tekst veranderen zoals gewenst, maar het kan soms ook de opmaak vernielen.

Dit komt omdat een alinea op zijn beurt uit individuele subobjecten bestaat. Elk van deze subobjecten bevat zijn eigen opmaak-informatie. Als het centrum van een alinea, bijvoorbeeld, een woord bevat dat is afgedrukt in vet, dan wordt het in Apache OpenOffice weergegeven door drie gedeelten van een alinea: het gedeelte vóór het type vet, het vette woord en tenslotte het gedeelte achter het type vet, dat normaal wordt weergegeven.

Als de tekst van de alinea nu wordt veranderd met de eigenschap String, dan verwijdert Apache OpenOffice eerst de oude gedeelten van de alinea en voegt nieuwe gedeelten voor een alinea in. De opmaak van de vorige gedeelten gaat dan verloren.

Om dit effect te voorkomen, kan de gebruiker beter toegang zoeken tot de de geassocieerde alinea-gedeelten, in plaats van tot de gehele alinea. Alinea's verschaffen voor dit doel hun eigen object Enumeration. Het volgende voorbeeld toont een dubbele lus die door alle alinea's van een tekstdocument en de alinea-gedeelten die zij bevatten gaat en past het proces van vervangingen uit het voorgaande voorbeeld daar op toe:

Dim Doc As Object
Dim Enum1 As Object
Dim Enum2 As Object
Dim TekstElement As Object
Dim TekstDeel As Object
 
Doc = ThisComponent
Enum1 = Doc.Text.createEnumeration
 
' ga door alle alinea's
While Enum1.hasMoreElements
  TekstElement = Enum1.nextElement
 
  If TekstElement.supportsService("com.sun.star.text.Paragraph") Then
    Enum2 = TekstElement.createEnumeration
    ' ga door alle gedeelten van alinea's 
 
    While Enum2.hasMoreElements
      TekstDeel = Enum2.nextElement
      MsgBox "'" & TekstDeel.String & "'"
      TekstDeel.String = Replace(TekstDeel.String, "you", "U") 
      TekstDeel.String = Replace(TekstDeel.String, "twee", "2")
      TekstDeel.String = Replace(TekstDeel.String, "vier", "4") 
    Wend
 
  End If
Wend

Het voorbeeld gaat door een tekstdocument in een dubbele lus. De buitenste lus refereert aan de alinea's van de tekst. De binnenste lus verwerkt de gedeelten van de alinea's in de alinea's. De voorbeeld-code wijzigt de inhoud in elk van deze gedeelten van alinea's met behulp van de eigenschap String van de tekenreeks, zoals het geval is in het voorgaande voorbeeld voor alinea's. Omdat echter de gedeelten van de alinea's direct worden bewerkt, blijft hun informatie voor de opmaak behouden bij het vervangen van de tekenreeks.

Opmaken

Er zijn verschillende manieren om tekst op te maken. De eenvoudigste manier is om de eigenschappen voor de opmaak direct aan de tekstreeks toe te wijzen. Dit wordt directe opmaak genoemd. Directe opmaak wordt in het bijzonder gebruikt in korte documenten omdat de opmaak door de gebruiker met de muis kan worden toegewezen. U kunt, bijvoorbeeld, een woord binnen een tekst accentueren door vet of regel centreren te gebruiken.

In aanvulling op directe opmaak, kunt u ook tekst opmaken met behulp van profielen. Dit wordt genoemd indirecte opmaak. Met indirecte opmaak wijst de gebruiker een vooraf gedefinieerd opmaakprofiel toe aan het relevante tekstgedeelte. Als het uiterlijk van de tekst op een later tijdstip wordt gewijzigd, hoeft de gebruiker alleen maar het opmaakprofiel te veranderen. Apache OpenOffice verandert dan de manier waarop alle tekstgedeelten die dit profiel gebruiken wordt weergegeven.

Documentation note.png VBA : In VBA zijn de eigenschappen voor opmaak van een object in het algemeen verspreid over een scala aan subobjecten (bijvoorbeeld Range.Font, Range.Borders, Range.Shading, Range.ParagraphFormat). De eigenschappen worden benaderd door middel van het stapelen van uitdrukkingen (bijvoorbeeld Range.Font.AllCaps). Aan de andere kant zijn in Apache OpenOffice BASIC de eigenschappen voor opmaak direct beschikbaar bij gebruik van de relevante objecten (TextCursor, Paragraph, enzovoort). U vindt een overzicht van de in Apache OpenOffice beschikbare eigenschappen voor tekens en alinea's in de volgende twee gedeelten.


Documentation note.png De eigenschappen voor opmaak kunnen in elk object (Paragraph, TextCursor, enzovoort) worden gevonden en kunnen direct worden toegepast.

Eigenschappen voor tekens

Deze eigenschappen voor opmaak, die refereren aan individuele tekens, worden omschreven als eigenschappen voor tekens. Deze omvatten ook het type vet en het lettertype. Objecten die toestaan dat eigenschappen van tekens worden ingesteld moeten de service com.sun.star.style.CharacterProperties ondersteunen. Apache OpenOffice herkent een heel bereik aan services die deze service ondersteunen. Deze omvatten ook de voorgaande beschreven services com.sun.star.text.Paragraph voor alinea's en ook de services com.sun.star.text.TextPortion voor gedeelten van alinea's.

De service com.sun.star.style.CharacterProperties verschaft geen interfaces, maar biedt in plaats daarvan een bereik aan eigenschappen waardoor eigenschappen voor tekens kunnen worden gedefinieerd en aangeroepen. Een complete lijst van alle eigenschappen voor tekens kan worden gevonden in de verwijzingen van de Apache OpenOffice API. De volgende lijst omschrijft de meest belangrijke eigenschappen:


CharFontName (String)
naam van het geselecteerde lettertype.
CharColor (Long)
tekstkleur.
CharHeight (Float)
hoogte van teken in punten (pt).
CharUnderline (groep Constanten)
type onderlijn (constanten die overeenkomen met com.sun.star.awt.FontUnderline ).
CharWeight (groep Constanten)
dikte lettertype (constanten die overeenkomen met com.sun.star.awt.FontWeight).
CharBackColor (Long)
kleur achtergrond.
CharKeepTogether (Boolean)
onderdrukken van automatisch regeleinde.
CharStyleName (String)
naam van opmaakprofiel van het teken.

Eigenschappen voor alinea's

Informatie over opmaak die niet refereert aan individuele tekens, maar aan de gehele alinea wordt beschouwd als een eigenschap voor een alinea. Dit behelst zowel de afstand van de alinea tot de rand van de pagina als ook de regelafstand. De alinea-eigenschappen zijn beschikbaar via de servicecom.sun.star.style.ParagraphProperties.

Zelfs de eigenschappen voor alinea's zijn beschikbaar in diverse objecten. Alle objecten die de service com.sun.star.text.Paragraph ondersteunen, geven ook ondersteuning voor de alinea-eigenschappen in com.sun.star.style.ParagraphProperties. Een volledige lijst van de eigenschappen voor alinea's kan worden gevonden in de verwijzingen van de Apache OpenOffice API. De meest algemene eigenschappen voor alinea's zijn:


ParaAdjust (enum)
verticale oriëntatie van de tekst (constanten die overeenkomen met com.sun.star.style.ParagraphAdjust ).
ParaLineSpacing (struct)
regelafstand (structuur die overeenkomt met com.sun.star.style.LineSpacing).
ParaBackColor (Long)
kleur achtergrond.
ParaLeftMargin (Long)
linkermarge in 100-en van een millimeter.
ParaRightMargin (Long)
rechtermarge in 100-en van een millimeter.
ParaTopMargin (Long)
bovenmarge in 100-en van een millimeter.
ParaBottomMargin (Long)
ondermarge in 100-en van een millimeter.
ParaTabStops (Array van structuur)
type en positie van tabs (array met structuren van het type com.sun.star.style.TabStop ).
ParaStyleName (String)
naam van het alineaopmaakprofiel.

Voorbeeld: eenvoudige HTML-export

Het volgende voorbeeld demonstreert hoe te werken met informatie over opmaak. Het herhaalt zich door een tekstdocument en maakt een eenvoudig HTML-bestand. Elke alinea wordt voor dit doel opgenomen in zijn eigen HTML-element <P>. Alineagedeelten, weergegeven in het type VET, worden gemarkeerd met behulp van een HTML-element <B> bij exporteren.

Dim BestandsNr As Integer, Bestandsnaam As String, HuidigeRegel As String
Dim Doc As Object   
Dim Enum1 As Object, Enum2 As Object
Dim TekstElement As Object, TekstDeel As Object
 
Bestandsnaam = "c:\text.html"
BestandsNr = Freefile
Open Bestandsnaam For Output As #BestandsNr   
Print #BestandsNr, "<HTML><BODY>"
Doc = ThisComponent
Enum1 = Doc.Text.createEnumeration
 
' lus door alle alinea's
While Enum1.hasMoreElements
  TekstElement = Enum1.nextElement
 
  If TekstElement.supportsService("com.sun.star.text.Paragraph") Then
    Enum2 = TekstElement.createEnumeration
    HuidigeRegel = "<P>"
 
    ' lus door alle gedeelten van alinea's
    While Enum2.hasMoreElements
      TekstDeel = Enum2.nextElement
 
      If TekstDeel.CharWeight = com.sun.star.awt.FontWeight.BOLD THEN
        HuidigeRegel = HuidigeRegel & "<B>" & TekstDeel.String & "</B>"
      Else
        HuidigeRegel = HuidigeRegel & TekstDeel.String
      End If
 
    Wend
 
    ' uitvoer van de regel
    HuidigeRegel = HuidigeRegel & "</P>"
    Print #BestandsNr, HuidigeRegel
  End If
 
Wend
 
' schrijven van laatste gedeelte HTML 
Print #BestandsNr, "</BODY></HTML>"
Close #BestandsNr

De basisstructuur van het voorbeeld is georiënteerd op de voorbeelden voor het doorlopen van de gedeelten van alinea's van een tekst zoals eerder besproken. De functie voor het schrijven van het HTML-bestand, net als de testcode die controleert op letterdikte van de corresponderende gedeelten en gedeelten van alinea's in type vet voorziet van een corresponderende HTML-tag, zijn toegevoegd.

Standaardwaarden voor eigenschappen van tekens en alinea's

Directe opmaak heeft altijd voorrang boven indirecte opmaak. Met andere woorden: aan opmaak met behulp van een profiel wordt een lagere prioriteit toegewezen dan aan directe opmaak van een tekst.

Vaststellen of een gedeelte van een document direct of indirect is opgemaakt, is niet gemakkelijk. De door Apache OpenOffice verschafte werkbalken tonen de algemene tekst-eigenschappen, zoals lettertype, dikte en afmeting. Echter, of de corresponderende instellingen zijn gebaseerd op een profiel of direct zijn opgemaakt in de tekst, is niet duidelijk.

Apache OpenOffice BASIC verschaft de methode getPropertyState, waarmee programmeurs kunnen controleren hoe een bepaalde eigenschap werd opgemaakt. Als een parameter gebruikt dit de naam van de eigenschap en geeft een constante terug die informatie verschaft over de oorsprong van de opmaak. De volgende terugkeerwaarden, die zijn gedefinieerd in de opsomming com.sun.star.beans.PropertyState, zijn mogelijk:


com.sun.star.beans.PropertyState.DIRECT_VALUE
de eigenschap is direct in de tekst gedefinieerd (directe opmaak)
com.sun.star.beans.PropertyState.DEFAULT_VALUE
de eigenschap is gedefinieerd door een opmaakprofiel (indirecte opmaak)
com.sun.star.beans.PropertyState.AMBIGUOUS_VALUE
de eigenschap is niet duidelijk. Deze status duikt, bijvoorbeeld, op bij het bevragen van de eigenschap type vet van een alinea, die zowel woorden in vet als in normaal lettertype weergeeft.

Het volgende voorbeeld toont hoe eigenschappen voor opmaak kunnen worden bewerkt in Apache OpenOffice. Het zoekt door een tekst naar gedeelten van alinea's die werden weergegeven als type vet met behulp van directe opmaak. Als het een corresponderend alinea-gedeelte tegenkomt, verwijdert het de directe opmaak met behulp van de methode setPropertyToDefault en wijst een tekenopmaakprofiel MijnVet toe aan het corresponderende gedeelte van de alinea.

Dim Doc As Object
Dim Enum1 As Object
Dim Enum2 As Object
Dim TekstElement As Object
Dim TekstDeel As Object
 
Doc = ThisComponent
Enum1 = Doc.Text.createEnumeration
 
' lus door alle alinea's
While Enum1.hasMoreElements
  TekstElement = Enum1.nextElement
 
  If TekstElement.supportsService("com.sun.star.text.Paragraph") Then
    Enum2 = TekstElement.createEnumeration
    ' lus door alle gedeelten van de alinea's
 
    While Enum2.hasMoreElements
      TekstDeel = Enum2.nextElement
 
      If TekstDeel.CharWeight = _
        com.sun.star.awt.FontWeight.BOLD AND _
        TekstDeel.getPropertyState("CharWeight") = _
        com.sun.star.beans.PropertyState.DIRECT_VALUE Then
          TekstDeel.setPropertyToDefault("CharWeight")
          TekstDeel.CharStyleName = "MijnVet" 
      End If
    Wend
  End If
Wend


Content on this page is licensed under the Public Documentation License (PDL).
Personal tools