Procedures en functies

From Apache OpenOffice Wiki
Jump to: navigation, search
Book.png


Procedures en functies vormen belangrijke punten in de structuur van een programma. Zij verschaffen het raamwerk om een complex probleem op te delen in verschillende sub-taken.

Procedures

Een procedure voert een actie uit zonder een expliciete waarde te verschaffen. Zijn syntaxis is

Sub Test
  ' ... hier staat de actuele code van de procedure
End Sub

Het voorbeeld definieert een procedure genaamd Test die code bevat die kan worden benaderd vanaf elk punt in het programma. De aanroep wordt gemaakt door de procedurenaam op de relevante plaats in het programma in te voeren:

Functies

Een function, net als een procedure, combineert een blok programma's om te worden uitgevoerd in één logische eenheid. Echter, anders dan een procedure, verschaft een functie een retourwaarde.

Function Test
  ' ... hier staat de actuele code van de functie
  Test = 123
End Function

De retourwaarde wordt toegewezen via een eenvoudige toewijzing. De toewijzing hoeft niet te worden geplaatst aan het einde van de functie, maar kan op elke plaats in de functie worden gemaakt.

De voorgaande functie kan als volgt worden aangeroepen binnen het programma:

Dim A
A = Test

De code definieert een variabele A en wijst daar het resultaat van de functie Test aan toe.

De retourwaarde kan binnen de functie meerdere malen worden overschreven. Zoals met klassieke toewijzing van variabelen, geeft de functie in dit voorbeeld de waarde weer die daaraan het laatste was toegekend.

Function Test
  Test = 12
  ' ... 
  Test = 123
End Function

In dit voorbeeld is de retourwaarde van de functie 123.


Als een toewijzing is gestopt, geeft de functie een waarde nul weer (getal 0 voor numerieke waarden en een blanco voor tekenreeksen).

De retourwaarde van een functie kan elk type zijn. Het type wordt gedeclareerd op dezelfde manier als een declaratie van een variabele:

Function Test As Integer
  ' ... hier staat de actuele code van de functie
End Function

Als het type retourwaarde niet is gespecificeerd (zie het eerste voorbeeld van deze pagina), geeft de functie een variant terug.

Voortijdig beëindigen van procedures en functies

In Apache OpenOffice BASIC, kunt u de opdrachten Exit Sub en Exit Function gebruiken om een procedure of functie voortijdig te beëindigen, bijvoorbeeld voor foutafhandeling. Deze opdrachten stoppen de procedure of functie en laten het programma terugkeren naar het punt waarop de procedure en/of functie werd aangeroepen.

Het volgende voorbeeld toont een procedure die verder uitvoering beëindigt als de variabele ErrorOccured de waarde True heeft.

Sub Test
  Dim ErrorOccured As Boolean
  ' ...
  If ErrorOccured Then
    Exit Sub
  End If
  ' ...
End Sub

Doorgeven van parameters

Functies en procedures kunnen één of meer parameters ontvangen. Essentiële parameters moeten worden omsloten door haken na de functie- of procedurenaam. Het volgende voorbeeld definieert een procedure die een Integer-waarde A en een tekenreeks B als parameters verwacht.

Sub Test (A As Integer, B As String)
  ' ...
End Sub

Parameters worden normaal gesproken in Apache OpenOffice Basic doorgegeven als verwijzing. Veranderingen, gemaakt in de variabelen, worden behouden als de procedure of functie wordt verlaten:

Sub Test 
  Dim A As Integer
  A = 10
  WijzigWaarde(A)
  ' De parameter A heeft nu de waarde 20
End Sub
 
Sub WijizgWaarde(DeWaarde As Integer)
  DeWaarde = 20
End Sub

In dit voorbeeld wordt de waarde A, die is gedefinieerd in de functie Test, doorgegeven als een parameter aan de functie WijzigWaarde. De waarde wordt dan veranderd naar 20 en doorgegeven aan DeWaarde, die wordt behouden als de functie wordt verlaten.

U kunt ook een parameter doorgeven als een waarde als u niet wilt dat opvolgende veranderingen in de parameter de oorspronkelijke waarde beïnvloeden. Zorg er voor dat het sleutelwoord ByVal voorafgaat aan de declaratie van de variabele in de kop van de functie om te specificeren dat een parameter moet worden doorgegeven als een waarde.

In het voorgaande voorbeeld zal, als we de functie WijzigWaarde vervangen, de bovenliggende variabele A niet beïnvloed worden door deze wijziging. Na de aanroep voor de functie WijzigWaarde behoudt de variabele A de waarde 10.

Sub WijzigWaarde(ByVal DeWaarde As Integer)
  DeWaarde = 20
End Sub
Documentation note.png VBA : De methode voor het doorgeven van parameters aan procedures en functies in Apache OpenOffice BASIC is virtueel identiek aan die in VBA. Standaard worden de parameters doorgegeven als verwijzing. Gebruik het sleutelwoord ByVal om parameters door te geven als waarden. In VBA kunt u ook het sleutelwoord ByRef gebruiken om te forceren dat een parameter wordt doorgegeven als een verwijzing. Apache OpenOffice BASIC herkent maar negeert dit sleutelwoord, omdat het al de standaardprocedure is in Apache OpenOffice BASIC.


Optionele parameters

Functies en procedures kunnen alleen worden aangeroepen als alle benodigde parameters worden doorgegeven bij het aanroepen.

Apache OpenOffice BASIC laat u parameters definiëren als optional, dat betekent dat als de corresponderende waarden niet zijn opgenomen in een aanroep, Apache OpenOffice BASIC een lege parameter doorgeeft. In het volgende voorbeeld is de parameter A verplicht, terwijl de parameter B optioneel is.

Sub Test(A As Integer, Optional B As Integer)
  ' ...
End Sub

De functie IsMissing controleert of een parameter is doorgegeven of is weggelaten.

Sub Test(A As Integer, Optional B As Integer)
  Dim B_Local As Integer
  ' Controleer of de parameter B ook echt aanwezig is         
  If Not IsMissing (B) Then   
    B_Local = B      ' parameter B aanwezig
  Else
    B_Local = 0      ' parameter B ontbreekt -> standaardwaarde 0
  End If
  ' ... Begint de eigenlijke functie
End Sub

Het voorbeeld test eerst of de parameter B is opgegeven en, indien nodig, geeft hij dezelfde parameter door aan de interne variabele B_Local. Als de corresponderende parameter niet aanwezig is, dan wordt de standaard-waarde (in dit geval de waarde 0) doorgegeven aan B_Local in plaats van de opgegeven parameter.

Documentation note.png VBA : Het in VBA aanwezige sleutelwoord ParamArray wordt niet ondersteund in Apache OpenOffice Basic.


Recursie

Een recursieve procedure of functie is er een die de mogelijkheid heeft om zichzelf aan te roepen totdat hij ontdekt dat aan een basisvoorwaarde wordt voldaan. Wanneer de functie wordt aangeroepen met de basisvoorwaarde, wordt een resultaat teruggegeven.

Het volgende voorbeeld gebruikt een recursieve functie om de faculteit van de getallen 42, -42 en 3.14 te berekenen:

Sub Main
  Msgbox BerekenFaculteit(  42 )    ' geeft weer 1,40500611775288E+51
  Msgbox BerekenFaculteit( -42 )    ' geeft weer "Ongeldig getal voor faculteit!"
  Msgbox BerekenFaculteit( 3.14 )   ' geeft weer "Ongeldig getal voor faculteit!"
End Sub 
 
Function BerekenFaculteit( Getal )
  If Getal < 0 Or Getal <> Int( Getal ) Then
    BerekenFaculteit = "Ongeldig getal voor faculteit!"
  ElseIf Getal = 0 Then
    BerekenFaculteit = 1
  Else
    ' Dit is de recursieve aanroep:
    BerekenFaculteit = Getal * CalculateFactorial( Getal - 1 )
  Endif
End Function

Het voorbeeld geeft de faculteit van het getal 42 terug door recursief de functie BerekenFaculteit aan te roepen totdat die de basisvoorwaarde 0! = 1 bereikt.

Documentation note.png De niveaus voor recursie zijn ingesteld op verschillende niveaus, gebaseerd op on het platform voor de software. Voor Windows is het niveau voor recursie 5800. Voor Solaris en Linux wordt een evaluatie van de grootte van de stapel uitgevoerd en wordt het niveau voor recursie berekend.


Content on this page is licensed under the Public Documentation License (PDL).
Personal tools