Werken met dialoogvensters

From Apache OpenOffice Wiki
Jump to: navigation, search
Book.png


Dialoogvensters van Apache OpenOffice BASIC bestaan uit een dialoogvenster dat velden, lijstvakken, radioknoppen en andere controle-elementen kan bevatten.

Dialoogvensters maken

U kunt dialoogvensters maken en structureren met behulp van de editor van Apache OpenOffice voor dialoogvensters:

Dialoogvensters maken en structureren in de editor voor dialoogvensters

U kunt de besturingselementen vanuit het ontwerp-palet (links) in het gebied van het dialoogvenster slepen, en hun positie en grootte definiëren.

Het voorbeeld toont een dialoogvenster dat een label en een keuzelijst bevat.

Een dialoogvenster dat een label en een keuzelijst bevat

U kunt een dialoogvenster openen met de volgende code:

Dim Dlg As Object
 
DialogLibraries.LoadLibrary("Standard")
Dlg = CreateUnoDialog(DialogLibraries.Standard.DlgDef)
Dlg.Execute()
Dlg.dispose()

CreateUnoDialog maakt een object genaamd Dlg dat verwijst naar het geassocieerde dialoogvenster. Vóórdat u een dialoogvenster kunt maken, moet u zich er van vergewissen dat de bibliotheek die het gebruikt (in dit voorbeeld de bibliotheek Standard) is geladen. Indien niet geladen, dan voert de methode LoadLibrary deze taak uit.

Als het dialoogvenster-object Dlg eenmaal is geïnitialiseerd, kunt u de methode Execute gebruiken om het dialoogvenster weer te geven. Dialoogvensters zoals deze worden omschreven als modal omdat zij geen andere actie van het programma toestaan totdat zij zijn gesloten. Zolang dit dialoogvenster geopend is, blijft het programma in de aanroep Execute.

De methode dispose aan het einde van de code geeft de bronnen, gebruikt door het dialoogvenster, vrij als het programma eenmaal eindigt.

Dialoogvensters sluiten

Sluiten met OK of Annuleren

Als een dialoogvenster een knop OK of Annulerenbevat, wordt het dialoogvenster automatisch gesloten als u op één van deze knoppen drukt. Meer informatie over de werking van deze knoppen wordt besproken in Besturingselementen voor dialoogvensters in detail.

Als u een dialoogvenster sluit met het klikken op de knop OK geeft de methode Execute een terugkeerwaarde van 1, anders wordt een waarde van 0 teruggegeven.

Dim Dlg As Object
 
DialogLibraries.LoadLibrary("Standard")
Dlg = CreateUnoDialog(DialogLibraries.Standard.MijnDialoogvenster)
Select Case Dlg.Execute() 
Case 1
  MsgBox "Op OK gedrukt"
Case 0 
  MsgBox "Op Annuleren gedrukt"
End Select

Sluiten met de knop Sluiten in de titelbalk

U kunt u een dialoogvenster sluiten door te klikken op de knop Sluiten in de titelbalk van het dialoogvenster. In dit geval geeft de methode Execute van het dialoogvenster de waarde 0 terug, hetzelfde als wanneer u op de knop Annuleren drukt.

Sluiten met een expliciete aanroep van het programma

Vanuit een routine die wordt aangeroepen bij een gebeurtenis van een besturingselement, bijv. drukken op een gewone knop, kunt u ook een geopend dialoogvenster sluiten met de methode endExecute:

Dlg.endExecute()

Het object dialoogvenster moet toegankelijk zijn vanuit de routine van d egebeurtenis. Een eenvoudige manier is om het te declareren als een variabele Private of Public gebruikelijk voor de routine voor het hoofd-dialoogvenster en de routine voor de gebeurtenis.

De methode execute van het dialoogvenster geeft de waarde 0 terug, wat dezelfde is als wanneer u op de knop Annuleren drukt.

De methode endDialog van het dialoogvenster is een verbetering van endExecute. Het argument er van specificeert de waarde die zal worden teruggegeven door de methode execute.

Dlg.endDialog(2)  ' Dlg.execute zal 2 teruggeven

Toegang tot individuele besturingselementen

Een dialoogvenster kan een aantal besturingselementen bevatten. U kunt toegang krijgen tot deze elementen via de methode getControl die het element bij zijn naam teruggeeft.

Dim Ctl As Object
 
Ctl = Dlg.getControl("MijnKnop")
Ctl.Label = "Nieuw label"

Deze code bepaalt het object voor het besturingselement MijnKnop en initialiseert dan de object-variabele Ctl met een verwijzing naar het element. Tenslotte stelt de code de eigenschap Label van het besturingselement in op de waarde Nieuw label.

Documentation note.png Anders dan identificaties in Apache OpenOffice BASIC, zijn de namen van de besturingselementen hoofdlettergevoelig.

Werken met het model van dialoogvensters en besturingselementen

De scheiding tussen zichtbare programma-elementen (View) en de gegevens van de documenten daarachter (Model) vinden plaats op vele plekken in de API van Apache OpenOffice. In aanvulling op de methoden en eigenschappen van besturingselementen, hebben zowel het dialoogvenster als de besturingselementen een ondergeschikt object Model . Dit object staat u directe toegang tot de inhoud van een dialoogvenster of een besturingselement toe.

In dialoogvensters is het onderscheid tussen gegevens en weergave niet altijd even helder als op andere gebieden van de API in Apache OpenOffice. Elementen van de API zijn beschikbaar via zowel de View als de Model.

De eigenschap Model verschaft programma-gecontroleerde toegang tot het model van het dialoogvenster en objecten van het besturingselement.

Dim cmdVolgende As Object
 
cmdVolgende = Dlg.getControl("cmdVolgende")
cmdVolgende.Model.Enabled = False

Dit voorbeeld deactiveert de knop cmdVolgende in het dialoogvenster Dlg met behulp van het modelobject van cmdVolgende.


Content on this page is licensed under the Public Documentation License (PDL).
Personal tools