Difference between revisions of "NL/Documentation/BASIC Guide/Interface Overview"

Latest revision as of 16:17, 9 February 2021

Programmeursgids voor BASIC

{{{parttitle}}}

[[{{{PrevPart}}}|< Vorige deel ]]

[[{{{NextPart}}}|Volgende deel >]]

• De taal van Apache OpenOffice Basic

• Overzicht van een programma in BASIC
• Werken met variabelen
• Tekenreeksen
• Getallen
• Booleaanse waarden
• Datum en tijd
• Arrays
• Bereik en levensduur van variabelen
• Constanten
• Operatoren
• Aftakken
• Loops
• Procedures en functies
• Foutafhandeling
• Andere instructies

• Runtime-bibliotheek

• Functies voor conversie
• Strings (Tekenreeksen)
• Datum en tijd
• Bestanden en mappen
• Bericht- en invoervakken
• Andere functies

• Introductie voor de API

• Universal Network Objects (UNO)
• Eigenschappen en methoden
• Modules, services en interfaces
• Gereedschap voor werken met UNO
• Overzicht van centrale interfaces

• Werken met documenten

• De StarDesktop
• Opmaakprofielen en sjablonen

• Tekstdocumenten

• De structuur van tekstdocumenten
• Tekstdocumenten bewerken
• Meer dan alleen tekst

• Werkbladdocumenten

• De structuur van werkbladdocumenten
  • Rijen en kolommen
  • Cellen en bereiken
  • Werkbladdocumenten opmaken
• Werkbladdoucmenten bewerken

• Tekeningen en presentaties

• De structuur van tekeningen
• Tekenobjecten bewerken
• Presentaties

• Grafieken (Diagrammen)

• Diagrammen gebruiken in werkbladen
• De structuur van diagrammen
• Typen diagram

• Databases

• SQL: een Query-taal
• Typen toegang tot database
• Gegevensbronnen
• Toegang tot database

• Dialoogvensters

• Werken met dialoogvensters
• Eigenschappen
• Gebeurtenissen
• Elementen voor beheer dialoogvenster

• Formulieren

• Werken met formulieren
• Besturingselementen Formulieren
• Database-formulieren

< Vorige pagina

Volgende pagina >

Sommige interfaces van Apache OpenOffice kunnen worden gevonden in vele delen van de Apache OpenOffice API. Zij definiëren reeksen van methoden voor abstracte taken welke kunnen worden toegepast voor verschillende problemen. Hier vindt u een overzicht van de meest voorkomende van deze interfaces.

De herkomst van de objecten wordt op een later punt in deze gids verklaard. Op dit punt worden slechts enkele van de abstracte aspecten van objecten, waarvoor de Apache OpenOffice API sommige centrale interfaces verschaft, besproken.

Context-afhankelijke objecten maken

De Apache OpenOffice API verschaft twee opties voor het creëren van objecten. Eén kan worden gevonden in de functie createUnoService, vermeld aan het begin van dit hoofdstuk. createUnoService maakt een object dat universeel kan worden gebruikt. Zulke objecten en services zijn ook bekend als context-onafhankelijke services.

In aanvulling op de context-onafhankelijke services, zijn er ook context-afhankelijke services waarvan de objecten alleen handig zijn in samenhang met een ander object. Een tekenobject voor een werkbladdocument kan daarom bijvoorbeeld alleen bestaan in samenhang met dat ene document.

Interface com.sun.star.lang.XMultiServiceFactory

Context-afhankelijke objecten worden normaal gesproken gemaakt door middel van een objectmethode, waar het object van afhankelijk is. De methode createInstance, welke wordt gedefinieerd in de interface XMultiServiceFactory, wordt speciaal gebruikt in de objecten document.

Het tekenobject kan bijvoorbeeld als volgt worden gemaakt door gebruik van een object werkbladdocument:

Dim RechthoekVorm As Object
RechthoekVorm = _
  Spreadsheet.createInstance("com.sun.star.drawing.RectangleShape")

Een sjabloon voor een alinea in een tekstdocument wordt op dezelfde manier gemaakt:

Dim Opmaakprofiel as Object
Opmaakprofiel = Textdocument.createInstance("com.sun.star.style.ParagraphStyle")

Benoemde toegang tot onderliggende objecten

De interfaces XNameAccess en XNameContainer worden gebruikt in objecten die onderliggende objecten bevatten, welke kunnen worden benaderd door een naam in een natuurlijke taal.

Terwijl XNameAccess toegang verleent tot de individuele objecten, neemt XNameContainer de invoeging, wijziging en verwijdering van elementen op zich.

Interface com.sun.star.container.XNameAccess

Een voorbeeld van het gebruik van XNameAccess wordt verschaft door het object sheets van een werkbladdocument. Het combineert alle bladen binnen het werkbladdocument. De individuele bladen worden benaderd vanuit het object Bladen met behulp van de methode getByName vanuit XNameAccess:

Dim Bladen As Object
Dim Blad As Object
 
Bladen = Spreadsheet.Sheets
Blad = Bladen.getByName("Blad1")

De methode getElementNames verschaft een overzicht van de namen van alle elementen. Als resultaat geeft het een gegevensveld weer waarin de namen staan. Het volgende voorbeeld toont hoe alle namen van elementen van een werkbladdocument daardoor kunnen worden bepaald en weergegeven in een lus:

Dim Bladen As Object
Dim BladNamen
Dim I As Integer
 
Bladen = Spreadsheet.Sheets
BladNamen = Bladen.getElementNames
 
For I=LBound(BladNamen) To UBound(BladNamen)
  MsgBox BladNamen(I)
Next I

De methode hasByName van de interface XNameAccess onthult of een onderliggend object met een bepaalde naam bestaat binnen het basis-object. Het volgende voorbeeld geeft daarom een bericht weer dat de gebruiker informeert of het object Spreadsheet een blad bevat met de naam Blad1.

Dim Bladen As Object
 
Bladen = Spreadsheet.Sheets
If Bladen.HasByName("Blad1") Then
  MsgBox "Blad1 beschikbaar"
Else
  MsgBox "Blad1 niet beschikbaar"
End If

Interface com.sun.star.container.XNameContainer

De interface XNameContainer behandelt het invoegen, verwijderen en wijzigen van onderliggende elementen in een basisobject. De verantwoordelijke functies zijn insertByName, removeByName en replaceByName.

Het volgende is een praktisch voorbeeld hiervan. Het roept een tekstdocument aan, dat een object StyleFamilies bevat en gebruikt die om op zijn beurt de sjablonen voor alinea's (Alinea-opmaakprofielen) van het document beschikbaar te maken.

Dim Opmaakprofielen As Object
Dim Alineaopmaakprofielen As Object
Dim NieuwOpmaakprofiel As Object   
 
Opmaakprofielen = Textdoc.StyleFamilies
Alineaopmaakprofielen = Opmaakprofielen.getByName("Alineaopmaakprofielen")
Alineaopmaakprofielen.insertByName("NieuwOpmaakprofiel", NieuwOpmaakprofiel)      
Alineaopmaakprofielen.replaceByName("GewijzigdOpmaakprofiel", NieuwOpmaakprofiel)   
Alineaopmaakprofielen.removeByName("OudeOpmaakprofiel")

De regel insertByName voegt het opmaakprofiel NieuwOpmaakprofiel in onder dezelfde naam in het object AlineaOpmaakprofielen. De regel replaceByName verandert het object achter GewijzigdOpmaakprofiel in NieuwOpmaakprofiel. Tenslotteverwijdert de aanroep removeByName het object achter OudeOpmaakprofiel uit AlineaOpmaakprofielen.

Op index gebaseerde toegang tot onderliggende objecten

De interfaces XIndexAccess en XIndexContainer worden gebruikt in objecten die onderliggende objecten bevatten en die benaderd kunnen worden via een index.

XIndexAccess verschaft de methoden om toegang te krijgen tot individuele objecten. XIndexContainer verschaft methoden voor het invoegen en verwijderen van elementen.

Interface com.sun.star.container.XIndexAccess

XIndexAccess verschaft de methoden getByIndex en getCount voor het aanroepen van de onderliggende objecten. getByIndex verschaft een object door middel van een bepaalde index. getCount geeft weer hoeveel objecten beschikbaar zijn.

Dim Bladen As Object
Dim Blad As Object
Dim I As Integer
 
Bladen = Spreadsheet.Sheets
 
For I = 0 to Bladen.getCount() - 1
  Blad = Bladen.getByIndex(I)
  ' Blad bewerken
Next I

Het voorbeeld toont een lus die één voor één door alle elementen van het werkblad gaat en een verwijzing voor elk bewaart in de object-variabele Blad. Merk op dat, bij het werken met de indexen, getCount het aantal elementen teruggeeft. Echter, de elementen in getByIndex zijn genummerd beginnend met 0. De variabele voor het tellen van de lus loopt daarom van 0 tot en met getCount()-1.

Interface com.sun.star.container.XIndexContainer

De interface XIndexContainer verschaft de functies insertByIndex en removeByIndex. De parameters worden op dezelfde wijze gestructureerd als de overeenkomende functies in XNameContainer.

Iteratieve toegang tot onderliggende objecten

In sommige gevallen kan een object een lijst bevatten van onderliggende objecten die niet kunnen worden benaderd door een naam of een index. In deze situaties zijn de interfaces XEnumeration en XenumerationAccess toe te passen. Zij verschaffen een techniek waardoor alle onderliggende elementen van objecten kunnen worden doorgegeven, stap voor stap, zonder directe adressering te gebruiken.

In sommige instanties zou een object een lijst met onderliggende objecten kunnen bevatten waartoe geen toegang kan worden verkregen op een naam of een index. In deze situaties zijn de interfaces toepasbaar. Zij verschaffen een mechanisme waardoor alle onderliggende elementen van een object kunnen worden gepasseerd, stap voor stap, zonder directe addressering te gebruiken.

Interfaces com.sun.star.container.XEnumeration en XenumerationAccess

Het basisobject moet de interface XEnumerationAccess verschaffen, die alleen een methode createEnumeration bevat. Dit geeft een hulp-object weer, dat op zijn beurt de interface XEnumeration verschaft met de methoden hasMoreElements en nextElement. Hierdoor heeft u dan toegang tot de onderliggende objecten.

Het volgende voorbeeld stapt door alle alinea's van een tekst:

Dim AlineaNummering As Object
Dim Alinea As Object
 
AlineaNummering = Textdoc.Text.createEnumeration
 
While AlineaNummering.hasMoreElements()
  Alinea = AlineaNummering.nextElement()
Wend

Het voorbeeld maakt eerst een hulp-object AlineaNummering. Dit geeft geleidelijk in een lus de individuele alinea's van de tekst weer. De lus wordt beëindigd zodra de methode hasMoreElements de waarde False weergeeft, wat aangeeft dat het einde van de tekst is bereikt.