Difference between revisions of "NL/Documentation/BASIC Guide/Files and Directories (Runtime Library)"

Latest revision as of 15:08, 26 August 2022

Programmeursgids voor BASIC

{{{parttitle}}}

[[{{{PrevPart}}}|< Vorige deel ]]

[[{{{NextPart}}}|Volgende deel >]]

• De taal van Apache OpenOffice Basic

• Overzicht van een programma in BASIC
• Werken met variabelen
• Tekenreeksen
• Getallen
• Booleaanse waarden
• Datum en tijd
• Arrays
• Bereik en levensduur van variabelen
• Constanten
• Operatoren
• Aftakken
• Loops
• Procedures en functies
• Foutafhandeling
• Andere instructies

• Runtime-bibliotheek

• Functies voor conversie
• Strings (Tekenreeksen)
• Datum en tijd
• Bestanden en mappen
• Bericht- en invoervakken
• Andere functies

• Introductie voor de API

• Universal Network Objects (UNO)
• Eigenschappen en methoden
• Modules, services en interfaces
• Gereedschap voor werken met UNO
• Overzicht van centrale interfaces

• Werken met documenten

• De StarDesktop
• Opmaakprofielen en sjablonen

• Tekstdocumenten

• De structuur van tekstdocumenten
• Tekstdocumenten bewerken
• Meer dan alleen tekst

• Werkbladdocumenten

• De structuur van werkbladdocumenten
  • Rijen en kolommen
  • Cellen en bereiken
  • Werkbladdocumenten opmaken
• Werkbladdoucmenten bewerken

• Tekeningen en presentaties

• De structuur van tekeningen
• Tekenobjecten bewerken
• Presentaties

• Grafieken (Diagrammen)

• Diagrammen gebruiken in werkbladen
• De structuur van diagrammen
• Typen diagram

• Databases

• SQL: een Query-taal
• Typen toegang tot database
• Gegevensbronnen
• Toegang tot database

• Dialoogvensters

• Werken met dialoogvensters
• Eigenschappen
• Gebeurtenissen
• Elementen voor beheer dialoogvenster

• Formulieren

• Werken met formulieren
• Besturingselementen Formulieren
• Database-formulieren

< Vorige pagina

Volgende pagina >

Werken met bestanden is een van de basistaken van een toepassing. De Apache OpenOffice API verschaft een groot scala aan objecten waarmee u kantoordocumenten kunt creëren, openen en aanpassen. Deze worden in detail gepresenteerd in Introductie voor de Apache OpenOffice API. Niettegenstaande dit, in sommige gevallen zult u direct het bestandssysteem moeten benaderen, zoeken in directory's of tekstbestanden bewerken. De runtime bibliotheek van Apache OpenOffice BASIC verschaft verscheidene fundamentele functies voor deze taken.

Sommige DOS-specifieke bestands- en mapfuncties worden niet langer verschaft in Apache OpenOffice, of hun functie is slechts beperkt. Bijvoorbeeld: ondersteuning voor de functies ChDir, ChDrive en CurDir wordt niet verschaft. Sommige DOS-specifieke eigenschappen worden niet langer gebruikt in functies die eigenschappen van bestanden verwachten als parameters (bijvoorbeeld om onderscheid te maken tussen verborgen en systeembestanden). Deze wijziging was nodig om het hoogst mogelijke niveau van platformonafhankelijkheid te bereiken voor Apache OpenOffice.

Beheren van bestanden

modus Compatibiliteit

Het argument en de functie CompatibilityMode verschaffen grotere compatibiliteit met VBA, door de werking van bepaalde functies te wijzigen. Het effect on een bepaalde functie wordt, hieronder, bij die functie beschreven.

Als een argument krijgt CompatibilityMode( waarde ) een Booleaanse waarde om de modus in te stellen of uit te schakelen. Als een functie geeft CompatibilityMode() de Booleaanse waarde van de modus terug.

CompatibilityMode( True ) 'modus instellen
CompatibilityMode( False) 'modus uitschakelen
 
Dim bModus as Boolean
bModus = CompatibilityMode()

Zoeken in mappen

De functie Dir in Apache OpenOffice BASIC is verantwoordelijk voor het zoeken door mappen naar bestanden en sub-mappen. Bij het eerste verzoek dient een tekenreeks, die het pad bevat naar de mappen die moeten worden doorzocht, te worden toegewezen aan Dir als diens eerste parameter. De tweede parameter van Dir specificeert het bestand of de map waarnaar moet worden gezocht. Apache OpenOffice BASIC geeft de naam weer van de eerste map die wordt gevonden. Om het volgende item te vinden, zou de functie Dir moeten worden gevraagd zonder parameters. Als de functie Dir geen item meer vindt, geeft het een lege tekenreeks weer.

Het volgende voorbeeld toont hoe de functie Dirkan worden gebruikt om alle bestanden, die zich bevinden in één map, kunnen worden opgevraagd. De procedure slaat de individuele bestandsnamen op in de variabele AlleBestanden en geeft die dan weer in een berichtenvenster.

Sub BestandenTonen
  Dim VolgendBestand As String
  Dim AlleBestanden As String
 
  AlleBestanden = ""
  VolgendBestand = Dir("C:\", 0)
 
  While VolgendBestand  <> ""
    AlleBestanden = AlleBestanden & Chr(13) &  VolgendBestand 
    VolgendBestand = Dir
  Wend
 
  MsgBox AlleBestanden
End Sub

De 0, gebruikt in de tweede parameter in de functie Dir, zorgt er voor dat 0 alleen de namen van bestanden weergeeft en mappen worden genegeerd. De volgende parameters kunnen hier worden gespecificeerd:

• 0 : geeft normale bestanden weer
• 16 : sub-mappen

Het volgende voorbeeld is nagenoeg hetzelfde als het voorgaande voorbeeld, maar de functie Dir transporteert de waarde 16 als een parameter, die de sub-mappen van een map laat weergeven in plaats van de bestandsnamen.

Sub MappenTonen
  Dim VolgendeMap As String
  Dim AlleMappen As String
 
  AlleMappen = ""
  VolgendeMap = Dir("C:\", 16)
 
  While VolgendeMap <> ""
    AlleMappen = AlleMappen & Chr(13) &  VolgendeMap
    VolgendeMap = Dir
  Wend
 
  MsgBox AlleMappen
End Sub

VBA : Indien gevraagd in Apache OpenOffice Basic, geeft de functie Dir, die de parameter 16 gebruikt, alleen de sub-mappen van een map weer. In VBA geeft de functie ook de namen van de normale bestanden weer zodat nadere controle is vereist om alleen de mappen op te halen. Bij het gebruiken van de functie CompatibilityMode ( true ) gedraagt Apache OpenOffice BASIC zich als VBA en de functie Dir, die parameter 16 gebruikt, geeft sub-mappen en namen van normale bestanden weer.

VBA : De in VBA verschafte opties voor het zoeken door mappen, specifiek naar bestanden met de eigenschappen verborgen, systeembestand, archief en volumenaam, bestaat niet in Apache OpenOffice BASIC omdat de overeenkomende functies voor het bestandssysteem niet beschikbaar zijn op alle besturingssystemen.

VBA : De specificaties voor het pad zoals vermeld in Dir mogen de tijdelijke plaatsaanduidingen * en ? gebruiken in zowel VBA als in Apache OpenOffice BASIC. In Apache OpenOffice BASIC kan de tijdelijke plaatsaanduiding * echter slechts het laatste teken van een bestandsnaam en/of bestandsextensie zijn, wat niet het geval is in VBA.

Maken en verwijderen van mappen

Apache OpenOffice BASIC verschaft de functie MkDir voor het maken van mappen.

MkDir ("C:\SubDir1")

Deze functie maakt mappen en sub-mappen. Alle benodigde mappen binnen een hiërarchie worden, indien vereist, ook gemaakt. Bijvoorbeeld: als alleen de map C:\SubDir1 bestaat, dan maakt de aanroep

MkDir ("C:\SubDir1\SubDir2\SubDir3\")

zowel de map C:\SubDir1\SubDir2 als de map C:\SubDir1\SubDir2\SubDir3.

De functie RmDir verwijdert mappen.

RmDir ("C:\SubDir1\SubDir2\SubDir3\")

Als de map mappen of bestanden bevat worden deze ook verwijderd. U zou daarom voorzichtig moeten zijn met het gebruik van RmDir.

VBA : In VBA hebben de functies MkDir en RmDir alleen invloed op de huidige map. Aan de andere kant kunnen MkDir en RmDir in Apache OpenOffice BASIC worden gebruikt om niveaus van mappen te maken of te verwijderen.

VBA : In VBA produceert RmDir een foutbericht als een map een bestand bevat. In Apache OpenOffice BASIC worden de map en alle bestanden daarin verwijderd. Als u de functie CompatibilityMode ( true ) gebruikt, zal Apache OpenOffice BASIC zich gedragen zoals VBA.

Kopiëren, hernoemen, verwijderen en bestaan controleren van bestanden

De volgende aanroep maakt een kopie van het bestand Bron met de naam Doel:

FileCopy(Bron, Doel)

Met behulp van de volgende functie kunt u het bestand OudeNaam hernoemen naar NieuweNaam. De syntaxis met het sleutelwoord As en het feit dat er geen komma wordt gebruikt gaat terug naar de wortels van de taal BASIC.

Name OudeNaam As NieuweNaam

De volgende aanroep verwijdert het bestand Bestandsnaam. Gebruik de functie RmDir als u de gehele map (inclusief de bestanden daarin) wilt verwijderen.

Kill(Bestandsnaam)

De functie FileExists kan worden gebruikt om te controleren of een bestand bestaat:

If FileExists(Bestandsnaam) Then 
  MsgBox "Bestand bestaat."
End If

Lezen en wijzigen van eigenschappen van bestanden

Bij het werken met bestanden, is het soms belangrijk om in staat te zijn de eigenschappen van bestanden vast te stellen, de tijd dat het bestand het laatst werd gewijzigd en de lengte van het bestand.

De volgende aanroep geeft enkele eigenschappen van het bestand weer.

Dim Attr As Integer
Attr = GetAttr(Bestandsnaam)

De teruggegeven waarde wordt verschaft als een bit-masker waarin de volgende waarden mogelijk zijn:

• 1 : bestand is Alleen-lezen
• 16 : naam van een map

Het volgende voorbeeld bepaalt het bit-masker van het bestand test.txt en controleert of het Alleen-lezen is of dat het een map is. Als geen van beide van toepassing is, wordt de tekenreeks "normaal" toegewezen aan BestandsOmschrijving.

Dim BestandsMasker As Integer
Dim BestandsOmschrijving As String
 
BestandsMasker = GetAttr("test.txt")
 
If (BestandsMasker AND 1) > 0 Then
  BestandsOmschrijving = BestandsOmschrijving & " alleen-lezen "
End IF
 
If (BestandsMasker AND 16) > 0 Then
  BestandsOmschrijving = BestandsOmschrijving & " map "
End IF
 
If BestandsOmschrijving = "" Then
  BestandsOmschrijving = " normaal "
End IF
 
MsgBox BestandsOmschrijving

VBA : De in VBA gebruikte vlaggen voor het bevragen van de eigenschappen van bestanden verborgen, systeembestand, archief en volumenaam worden niet ondersteund in Apache OpenOffice BASIC omdat zij specifiek voor Windows zijn en niet of slechts gedeeltelijk aanwezig zijn op andere besturingssystemen.

De functie SetAttr maakt het mogelijk de eigenschappen van een bestand te wijzigen. De volgende aanroep kan daarom worden gebruikt om een bestand te voorzien van de status Alleen-lezen:

SetAttr("test.txt", 1)

Een bestaande status Alleen-lezen kan wordne verwijderd met de volgende aanroep:

SetAttr("test.txt", 0)

De datum en tijd van de laatste wijziging in een bestand worden verschaft door de functie FileDateTime. De datum wordt hier opgemaakt overeenkomstig de land-specifieke instellingen die worden gebruikt op het systeem.

FileDateTime("test.txt")   ' Geeft de datum en tijd van de laatste wijziging aan
                           ' het bestand.

De functie FileLen bepaalt de lengte van een bestand in bytes (als long integer waarde).

FileLen("test.txt")      ' Geeft de lengte van het bestand in bytes

Schrijven en lezen van tekstbestanden

Apache OpenOffice BASIC verschaft een breed scala van methoden om bestanden te lezen en te schrijven. De volgende uitleg heeft betrekking op het werken met tekstbestanden (niet tekstdocumenten).

Schrijven van tekstbestanden

Voordat een bestand kan worden benaderd, moet het eerst worden geopend. Om dit te doen is een vrije bestand behandelaar nodig, die duidelijk het bestand aanduidt voor aansluitende toegang tot het bestand.

De functie FreeFile wordt gebruikt om een vrije bestandsbehandelaar te maken.

BestandsNr = FreeFile

BestandsNr is een variabele Integer die de bestandsbehandelaar ontvangt. De behandelaar wordt dan gebruikt als een parameter voor de instructie Open, die het bestand opent.

De aanroep Open om een bestand te openen zodat het als een tekstbestand kan wordne geschreven is:

Open Bestandsnaam For Output As #BestandsNr

Bestandsnaam is een tekenreeks die de naam van het bestand bevat. BestandsNr is de behandelaar die is gemaakt door de functie FreeFile.

Als het bestand eenmaal is geopend kan de instructie Print de inhoud van het bestand, regel voor regel, maken:

Print #BestandsNr, "Dit is een testregel."

BestandsNr staat ook hier voor de bestandsbehandelaar. De tweede parameter specificeert de tekst die moet worden opgeslagen als een regel in het tekstbestand.

Als het proces van schrijven is voltooid moet het bestand worden gesloten met behulp van de aanroep Close:

Close #BestandsNr

De bestandsbehandelaar moet hier opnieuw gespecificeerd worden.

Het volgende voorbeeld geeft weer hoe een tekstbestand wordt geopend, er naar wordt geschreven en wordt gesloten:

Dim BestandsNr As Integer
Dim HuidigeRegel As String
Dim Bestandsnaam As String
 
Bestandsnaam = "c:\data.txt"        ' Definieer bestandsnaam 
BestandsNr = FreeFile               ' Maak een vrije bestandsbehandelaar
 
Open Bestandsnaam For Output As #BestandsNr        ' Open bestand (modus schrijven)
Print #BestandsNr, "Dit is een regel tekst"        ' Sla regel op 
Print #BestandsNr, "Dit is een andere regel tekst" ' Sla regel op 
Close #BestandsNr                                  ' Sluit bestand

Lezen van tekstbestanden

Tekstbestanden worden op dezelfde wijze gelezen als ze worden geschreven. De instructie Open, gebruikt om het bestand te openen, bevat de uitdrukking For Input in plaats van de uitdrukking For Output en, in plaats van de opdracht Print voor het schrijven van gegevens, moet de instructie Line Input worden gebruikt om de gegevens te lezen.

Tenslotte wordt, bij het aanroepen van een tekstbestand, de instructie eof gebruikt om te controleren of het einde van het bestand is bereikt:

eof(BestandsNr)

Het volgende voorbeeld geeft weer hoe een tekstbestand kan worden gelezen:

Dim BestandsNr As Integer
Dim HuidigeRegel As String
Dim Bestand As String
Dim Bericht as String
 
' Definier de bestandsnaam 
Bestand = "c:\data.txt"
 
' Maak de vrije bestandsbehandelaar
BestandsNr = Freefile
 
' Open het bestand (modus Lezen)
Open Bestand For Input As BestandsNr
 
' Controleer of het einde van het bestand is bereikt
Do While not eof(BestandsNr)
  ' Lees regel 
  Line Input #BestandsNr, HuidigeRegel   
  If HuidigeRegel <>"" then
    Bericht = Bericht & HuidigeRegel & Chr(13)
  end if
Loop
 
' Sluit het bestand 
Close #BestandsNr               
Msgbox Bericht

De individuele regels worden gevonden door een lus Do While, opgeslagen in de variabele Msg en aan het einde weergegeven in een berichtenvenster.