Arrays (matrices)
In aanvulling op eenvoudige variabelen (scalairen), ondersteunt Apache OpenOffice BASIC ook matrices (arrays/gegevensvelden). Een gegevensveld bevat verschillende variabelen, welke worden benaderd door middel van een index.
Definiëren van arrays
Arrays kunnen als volgt worden gedefinieerd:
Eenvoudige arrays
Een declaratie voor een array komt overeen met die van een declaratie voor een eenvoudige variabele. Echter, anders dan bij de variabele declaratie, wordt de naam van de array gevolgd door haken die de specificaties bevatten voor het aantal elementen. De expressie
Dim MyArray(3)
declareert een array die vier variabelen heeft van het gegevenstype Variant, namelijk MyArray(0), MyArray(1), MyArray(2) en MyArray(3).
U kunt ook type-specifieke variabelen declareren in een array. De volgende regel declareert, bijvoorbeeld, een array met vier Integer-variabelen:
Dim MyInteger(3) As Integer
In het voorgaande voorbeeld, begint de index voor het bereik altijd met de standaard startwaarde van nul. Als alternatief kan een geldigheidsbereik met start- en eindwaarden worden gespecificeerd voor de declaratie van het gegevensveld. Het volgende voorbeeld declareert een gegevensveld dat zes Integer-waarden heeft en kan worden benaderd met behulp van de indexnummers 5 tot en met 10:
Dim MyInteger(5 To 10) As Integer
De indexnummers behoeven geen positieve waarden te zijn. Het volgende voorbeeld toont ook een juiste declaratie, maar met negatieve grenzen voor het gegevensveld:
Dim MyInteger(-10 To -5) As Integer
It declares an integer data field with 6 values that can be addressed using the indexes -10 to -5.
There are no practical limits on the indexes or on the number of elements in an array, so long as there is enough memory:
Dim s(-53000 to 89000) As String s(-52000) = "aa" s(79999) = "bb" print s(-52000), s(79999)
 |
VBA : Other limit values sometimes apply for data field indexes in VBA. The same also applies to the maximum number of elements possible per dimension. The values valid there can be found in the relevant VBA documentation. |
Specified Value for Start Index
The start index of a data field usually begins with the value 0. Alternatively, you can change the start index for all data field declarations to the value 1 by using the call:
Option Base 1The call must be included in the header of a module if you want it to apply to all array declarations in the module. However, this call does not affect the UNO sequences that are defined through the Apache OpenOffice API whose index always begins with 0. To improve clarity, you should avoid using Option Base 1.
The number of elements in an array is not affected if you use Option Base 1, only the start index changes. The declaration
Option Base 1 ' ... Dim MyInteger(3)
creates 4 integer variables which can be described with the expressions MyInteger(1), MyInteger(2), MyInteger(3), and MyInteger(4).
|
VBA : In Apache OpenOffice Basic, the expression Option Base 1 does not affect the number of elements in an array as it does in VBA. It is, rather, the start index which moves in Apache OpenOffice Basic. While the declaration MyInteger(3) creates three integer values in VBA with the indexes 1 to 3, the same declaration in Apache OpenOffice Basic creates four integer values with the indexes 1 to 4. By using Option Compatible, Apache OpenOffice Basic behaves like VBA. |
Multi-Dimensional Data Fields
In addition to single dimensional data fields, Apache OpenOffice Basic also supports work with multi-dimensional data fields. The corresponding dimensions are separated from one another by commas. The example
Dim MyIntArray(5, 5) As Integer
defines an integer array with two dimensions, each with 6 indexes (can be addressed through the indexes 0 to 5). The entire array can record a total of 6 x 6 = 36 integer values.
You can define hundreds of dimensions in Apache OpenOffice Basic Arrays; however, the amount of available memory limits the number of dimensions you can have.
Dynamic Changes in the Dimensions of Data Fields
The previous examples are based on data fields of a specified dimension. You can also define arrays in which the dimension of the data fields dynamically changes. For example, you can define an array to contain all of the words in a text that begin with the letter A. As the number of these words is initially unknown, you need to be able to subsequently change the field limits. To do this in Apache OpenOffice Basic, use the following call:
ReDim MyArray(10)
|
VBA : Unlike VBA, where you can only dimension dynamic arrays by using Dim MyArray(), Apache OpenOffice Basic lets you change both static and dynamic arrays using ReDim. |
The following example changes the dimension of the initial array so that it can record 11 or 21 values:
Dim MyArray(4) As Integer ' Declaration with five elements ' ... ReDim MyArray(10) As Integer ' Increase to 11 elements ' ... ReDim MyArray(20) As Integer ' Increase to 21 elements
When you reset the dimensions of an array, you can use any of the options outlined in the previous sections. This includes declaring multi-dimensional data fields and specifying explicit start and end values. When the dimensions of the data field are changed, all contents are lost. If you want to keep the original values, use the Preserve command:
Dim MyArray(10) As Integer ' Defining the initial ' dimensions ' ... ReDim Preserve MyArray(20) As Integer ' Increase in ' data field, while ' retaining content
When you use Preserve, ensure that the number of dimensions and the type of variables remain the same.
|
VBA : Unlike VBA, where only the upper limit of the last dimension of a data field can be changed through Preserve, Apache OpenOffice Basic lets you change other dimensions as well. |
If you use ReDim with Preserve, you must use the same data type as specified in the original data field declaration.
Determining the Dimensions of Data Fields
Functions LBound() and UBound() return respectively the lowest permitted index value and the highest permitted index value of an array. This is useful when an array has changed its dimensions.
Dim MyArray(10) As Integer ' ... some instructions Dim n As Integer n = 47 ' could be the result of a computation Redim MyArray(n) As Integer MsgBox(LBound(MyArray)) ' displays : 0 MsgBox(UBound(MyArray)) ' displays : 47
For a multi-dimensional array you need to specify the position (1 to n) of the index you want to know the permitted lower and upper values:
Dim MyArray(10, 13 to 28) As Integer MsgBox(LBound(MyArray, 2)) ' displays : 13 MsgBox(UBound(MyArray, 2)) ' displays : 28
Empty arrays
In some cases, especially when dealing with the API, you need to declare an empty array. Such array is declared without dimension, but may later be filled by an API function or with a Redim statement:
Dim s() As String ' declare an empty array ' --- later in the program ... Redim s(13) As String
You cannot assign a value to an empty array, since it does not contain any elements.
The "signature" of an empty array is that UBound() returns -1 and LBound() returns 0:
Dim MyArray() As Integer MsgBox(LBound(MyArray)) ' displays : 0 MsgBox(UBound(MyArray)) ' displays : -1
Some API functions return an array containing elements (indexed from zero) or return an empty array. Use UBound() to check if the returned array is empty.
Defining values for arrays
Values for the Array fields can be stored like this:
MyArray(0) = "somevalue"
Accessing Arrays
Accessing values in an array works like this:
MsgBox("Value:" & MyArray(0))
Array Creation, value assignment and access example
And example containing all steps that show real array usage:
Sub TestArrayAxess
Dim MyArray(3)
MyArray(0) = "lala"
MsgBox("Value:" & MyArray(0))
End Sub
| Content on this page is licensed under the Public Documentation License (PDL). |
