FR/Documentation/Calc: fonction RECHERCHE

RECHERCHE

Renvoie une valeur d'une table large d'une cellule unique, à une position trouvée par la recherche dans une autre table.

Syntaxe :

RECHERCHE(valeur_recherchée; table_recherche; table_résultat)

valeur_recherchée est une valeur (nombre, texte ou valeur logique) à rechercher dans une ligne unique ou une plage de colonne/matrice unique table_recherche. table_recherche doit être triée, avec les nombres en ordre ascendants apparaissant avant les valeurs texte dans l'ordre alphabétique.

table_résultat est une plage/matrice de la même taille que table_recherche. RECHERCHE renvoie la valeur dans table_résultat à la position ou la correspondance a été trouvée dans table_recherche.

RECHERCHE décide d'où dans table_recherche valeur_recherchée va apparaître. S'il y a une correspondance exacte, c'est la position trouvée ; s'il y a plus d'une correspondance exacte, la position trouvée n'est pas nécessairement la position la plus à gauche/la plus haute. S'il n'y a pas de correspondance exacte, la position juste avant où valeur_recherchée doit apparaître est trouvée ; il résulte une erreur #N/A si cette position n'est pas dans table_recherche.

La correspondance est toujours insensible à la casse - le paramètre de casse dans la fenêtre de dialogue Outils - Options - OpenOffice.org Calc - Calcul ne s'applique pas.

Utilisation avancée :

Si expression régulières est activé dans Outils - Options - OpenOffice.org Calc - Calcul , RECHERCHE trouvera les correspondances exactes en traitant valeur_recherchée comme une expression régulière. Cela n'a de sens et ne doit être utilisé que si vous souhaitez trouver des correspondances exactes uniques.

Si 'Critères de recherche = et <> doivent correspondrent à des cellules entières' est activé dans la boîte de dialogue Outils - Options - OpenOffice.org Calc - Calcul, valeur_recherchée doit correspondre à tout le texte dans la cellule ; sinon, il peut juste correspondre à une partie du texte.

Exemples :

Dans ces exemples, les cellules A1, B1, C1, D1, E1 contiennent 3, 5, chat, mat, matter, et les cellules A3, B3, C3, D3, E3 contiennent A, B, C, D, E.

RECHERCHE(3; A1:E1; A3:E3)

renvoie A. La cellule A1 correspond à 3. Le contenu de la cellule correspondante dans A3:E3 est renvoyé.

RECHERCHE(7; A1:E1; A3:E3)

renvoie B. 7 doit apparaître entre 5 et chat, ainsi la position à gauche est trouvée.

RECHERCHE(1; A1:E1; A3:E3)

renvoie #N/A. 1 doit apparaître avant 3 dans la ligne supérieure et il n'y a pas de position à gauche dans la table.

RECHERCHE("CHAT"; A1:E1; A3:E3)

renvoie C. La différence entre minuscule et majuscule est ignorée, ainsi CHAT correspond à chat.

RECHERCHE("mate"; A1:E1; A3:E3)

renvoie D. mate doit apparaître entre mat et matter, ainsi la position à gauche est trouvée.

Utilisation avancée : expressions régulières

RECHERCHE("ch.t"; A1:E1; A3:E3)

renvoie C si les expressions régulières sont activées (et #N/A sinon). Le point '.' signifie 'pour tout caractère unique' dans une expression régulière, ainsi ch.t correspond à chat.

RECHERCHE(".at"; A1:E1; A3:E3)

".at" correspond à la fois à chat and mat si les expressions régulières sont activées. Cela correspond aussi à matter si la correspondance aux lignes entières est désactivée. Il n'est pas possible de prédire quelle correspondance sera trouvée, ni quel résultat va être renvoyé. Utilisez les expressions régulières avec précaution.

Voir également :

CHOSIR, RECHERCHEH, INDEX, EQUIV, DECALER, RECHERCHEV

PROBABILITE

Expressions régulières dans Calc

Fonctions classeur

Fonctions listées alphabétiquement, Fonctions listées par catégories

Issues :

• La sensibilité à la casse est discutée sur l'issue 71000
• Dans Excel, toute valeur logique dans table_recherche doit apparaître après toute valeur texte. Dans Cacl, les valeurs logiques sont supposées avoir les valeurs numérique 0 (FAUX) et 1 (VRAI).
• La flexibilité et la puissance des expressions régulières et l'option pour désactiver la correspondance sur une ligne entière rend cette fonction très complexe. La façon la plus simple et sécurisée d'utiliser cette fonction est de désactiver les expressions régulières et d'activer la recherche sur une ligne entière.
• Le futur standard ODFF définit une version à deux paramètres de cette fonction qui sera implémentée dans Calc (issue 74245).
• Le futur standard ODFF suggère que les paramètres table_recherche et la table_résultat soient évalusé comme des formules de matrice. Ce n'est pas le cas dans Calc (issue 90628).

Content on this page is licensed under the Public Documentation License (PDL).