NL/Documentation/How Tos/Calc: functie SOM.ALS

From Apache OpenOffice Wiki
Jump to: navigation, search


SOM.ALS

Telt, onder voorwaarden, de inhoud van cellen in een bereik bij elkaar op.

Syntaxis:

SOM.ALS(test_bereik; voorwaarde; som_bereik)

Deze functie identificeert die cellen in het bereik test_bereik die voldoen aan de voorwaarde, en telt de inhoud van de corresponderende cellen bij elkaar op in het bereik som_bereik. Als som_bereik wordt weggelaten worden de cellen in test_bereik bij elkaar opgeteld.
voorwaarde kan zijn:
een getal, zoals 34,5
een uitdrukking, zoals 2/3 of WORTEL(B5)
een tekenreeks van tekst
SOM.ALS zoekt naar cellen in test_bereik die gelijk zijjn aan voorwaarde, tenzij voorwaarde een tekenreeks van tekst is die begint met een vergelijkingsteken:
>, <, >=, <=, =, <>
In dat geval vergelijkt SOM.ALS deze cellen in test_bereik met het restant van de tekenreeks van tekst (indien mogelijk geïnterpreteerd als een getal en anders als tekst).
De voorwaarde “>4,5” test bijvoorbeeld of de inhoud van elke cel groter is dan het getal 4,5 en de voorwaarde “<hond” test of de inhoud van elke cel alfabetisch vóór de tekst hond zou komen.
Het kan zeer belangrijk zijn om de instellingen te controleren in het dialoogvenster Extra → Opties → OpenOffice Calc → Berekenen:
Indien het keuzevakje vóór Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn is geselecteerd, dan zal de voorwaarde “rood” alleen overeenkomen met rood; indien niet geselecteerd zal het overeenkomen met rood, Brood en rood licht.
Indien het keuzevakje vóór Reguliere expressies in formules mogelijk is geselecteerd, zal de voorwaarde overeenkomen met behulp van reguliere expressies - dus bijvoorbeeld "r.d" zal overeenkomen met red, rod, rid en "red.*" zal overeenkomen met red, reden, redden.
Het keuzevak vóór Hoofdletters/kleine letters heeft geen effect (er wordt geen aandacht besteed aan hoofd-/kleine letters). Bekijk de voorbeelden om te zien hoe een overeenkomende hoofdlettergevoelige overeenkomst wordt bereikt.
Blanco (lege) cellen in test_bereik worden genegeerd (zij voldoen nooit aan de voorwaarde).
voorwaarde kan slechts één enkele voorwaarde specificeren. Zie Optellen en tellen met voorwaarden voor manieren om meerdere voorwaarden te specificeren.

Voorbeeld:

SOM.ALS(A1:A9;"<0")

geeft de som terug van de negatieve getallen in A1:A9.

SOM.ALS(A1:A9; F1)

waar F1 de tekst >=0 (zonder dubbele aanhalingstekens) bevat, geeft de som van de positieve getallen in A1:A9 terug.

SOM.ALS(B2:B4; "<"&F2; C2:C4)

waar F2 bevat 10 en de cellen B2, B3, B4 bevatten 7, 9, 11, geeft de som van C2 en C3, omdat de cellen B2 en B3 kleiner zijn dan 10.

SOM.ALS(D1:D9; "appels"; E1:E9)

waar de cellen in D1:D9 ofwel appels of peren bevatten en de cellen in E1:E9 de overeenkomstige hoeveelheid van elk fruit bevatten, geeft de totale hoeveelheid appels terug.
Gevorderd onderwerp:

SOMPRODUCT(D1:D9="Appels"; E1:E9).

geeft de som van de items in E1:E9 terug waarvan het corresponderende item in D1:D9 overeenkomt met Appels, met identieke hoofdletters (items als appels en APPELS zouden niet overeen komen). Zie Optellen en tellen met voorwaarden voor details.

Zie ook

Personal tools
In other languages