NL/Documentation/How Tos/Calc: functie HORIZ.ZOEKEN

HORIZ.ZOEKEN

Geeft een waarde uit een tabelrij terug, die werd gevonden door een zoekactie in de eerste rij.

Syntaxis:

HORIZ.ZOEKEN(opzoekwaarde; gegevenstabel; rijindex; modus)

opzoekwaarde is een waarde (getal, tekst of logische waarde) om op te zoeken in de bovenste rij van het bereik/de matrix gegevenstabel. Als een waarde overeenkomt met de bovenste rij, geeft HORIZ.ZOEKEN de overeenkomende waarde (in dezelfde kolom) terug uit de rijindex^e rij van gegevenstabel, waar rijindex = 1 de bovenste rij is.

Als modus 0 is of ONWAAR, mag de bovenste rij van gegevenstabel ongeordend zijn, en wordt de eerste exacte overeenkomst gevonden (zoekend van links naar rechts).

Als modus 1 of WAAR, of wordt weggelaten, moet de bovenste rij van gegevenstabel gesorteerd zijn, met getallen in oplopende volgorde vóór tekstwaarden in alfabetische volgorde. HORIZ.ZOEKEN bepaalt waar in de bovenste rij opzoekwaarde moet verschijnen. Als er een exacte overeenkomst is, is dat de gevonden kolom; als er meer dan één exacte overeenkomst is, is de gevonden kolom niet noodzakelijkerwijze de meest linker. Als er geen exacte overeenkomst is, wordt de kolom links van waar waarde zou moeten verschijnen in de bovenste rij gevonden; de fout #N/B is het resultaat als die kolom niet in de tabel aanwezig is.

Als reguliere expressies zijn ingeschakeld in het dialoogvenster Extra - Opties - OpenOffice.org Calc - Berekenen, zal HORIZ.ZOEKEN exacte overeenkomsten vinden waarbij opzoekwaarde wordt behandeld als een * reguliere expressie. Dit heeft alleen zin en zou alleen moeten worden gebruikt als modus 0 is of ONWAAR.

Als 'Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn' is ingeschakeld in het dialoogvenster Extra - Opties - OpenOffice.org Calc - Berekenen, moet opzoekwaarde overeenkomen met de gehele tekst in de cel; indien niet, kan het overeenkomen met elk gedeelte van de tekst.

Het overeenkomen is altijd hoofdletterongevoelig - de instelling hoofd-/kleine letters in het dialoogvenster Extra - Opties - OpenOffice.org Calc - Berekenen is niet van toepassing.

Voorbeelden:

In deze voorbeelden bevatten de cellen A1, B1, C1, D1, E1 3, 5, kat, mat en matten, en de cellen A2, B2, C2, D2 en E2 bevatten A, B, C, D en E.

HORIZ.ZOEKEN(3; A1:E2; 2; 0)

geeft A terug. Cel A1 in de bovenste rij komt overeen met 3. De inhoud van de overeenkomstige cel op de 2^e rij (dat is, A2) wordt weergegeven. De bovenste rij is weliswaar gesorteerd, maar dit is niet nodig in de modus 0.

HORIZ.ZOEKEN(4; A1:E2; 2; 0)

geeft #N/B terug. Er is geen overeenkomst voor 4.

HORIZ.ZOEKEN("KAT"; A1:E2; 2; 0)

geeft C terug. Het verschil tussen hoofd- en kleine letters wordt genegeerd, dus KAT komt overeen met kat.

HORIZ.ZOEKEN("k.t"; A1:E2; 2; 0)

geeft C terug als reguliere expressies zijn ingeschakeld (en #N/B indien niet). De punt '.' staat voor 'elk enkel teken' in een reguliere expressie, dus komt k.t overeen met kat.

HORIZ.ZOEKEN(".at"; A1:E2; 2; 0)

geeft C terug als reguliere expressies zijn ingeschakeld. kat komt overeen; als ook mat, maar de meest linker overeenkomst wordt altijd gevonden in modus 0.

HORIZ.ZOEKEN("at"; A1:E2; 2; 0)

geeft #N/B terug als 'Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn' is ingeschakeld en anders C. at komt niet overeen met de inhoud van een gehele cel, maar komt overeen met een gedeelte van kat.

HORIZ.ZOEKEN(3; A1:E2; 2; 0)

geeft A terug. Cel A1 in de bovenste rij komt overeen met 3. De bovenste rij moet gesorteerd zijn in modus 1, waarbij tekst na getallen komt. matten volgt op mat omdat, hoewel de eerste letters hetzelfde zijn, matten meer letters heeft.

HORIZ.ZOEKEN(4; A1:E2; 2; 1)

geeft A terug. 4 zal verschijnen tussen 3 en 5 in de bovenste rij, dus wordt de positie aan de linkerzijde gevonden.

HORIZ.ZOEKEN(1; A1:E2; 2; 1)

geeft #N/B terug. 1 zal verschijnen voor 3 in de bovenste rij, en er is geen positie links daarvan in de tabel.

HORIZ.ZOEKEN(7; A1:E2; 2; 1)

geeft B terug. 7 zal verschijnen tussen 5 en kat in de bovenste rij, dus wordt de positie aan de linkerzijde gevonden.

HORIZ.ZOEKEN("appel"; A1:E2; 2; 1)

geeft B terug. appel zal verschijnen tussen 5 en kat in de bovenste rij, dus wordt de positie links daarvan gevonden.

HORIZ.ZOEKEN("mate"; A1:E2; 2; 1)

geeft D terug. mate zal verschijnen tussen mat en matten in de bovenste rij, dus wordt de positie links daarvan gevonden.

HORIZ.ZOEKEN("rat"; A1:E2; 2; 1)

geeft E terug. rat zal verschijnen na matten in de bovenste rij, dus wordt de positie links daarvan gevonden.

HORIZ.ZOEKEN("at"; A1:E2; 2; 1)

geeft B terug, zelfs als 'Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn' is uitgeschakeld. In dit geval wordt de overeenkomst tussen at en kat genegeerd ten faveure van het behandelen van at als één woord dat komt tussen 5 en kat.