NL/Documentation/How Tos/Calc: functie CEL

From Apache OpenOffice Wiki
< NL‎ | Documentation‎ | How Tos
Revision as of 13:16, 30 November 2009 by Ccornell (Talk | contribs)

(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
Jump to: navigation, search


CEL

Geeft informatie terug over het adres, opmaak of inhoud van een cel.


Syntaxis:

CEL(info_type; cel_verw)

geeft informatie over de cel cell_verw. De teruggegeven informatie is afhankelijk van de (hoofdletter ongevoelige) tekst-tekenreeks info_type, die als volgt kan worden ingesteld:
COL
CEL() geeft het getal van de kolom waarnaar verwezen wordt. Bijvoorbeeld:
CEL("COL"; D2) geeft 4 terug, omdat D de vierde kolom is.
ROW
CEL() geeft het getal van de rij waarnaar verwezen wordt. Bijvoorbeeld:
CEL("ROW"; D2) geeft 2 terug.
SHEET
CEL() geeft het getal van het blad waarnaar verwezen wordt. Voorbeeld:
CELL("SHEET"; Blad3.D2) geeft 3 terug, er van uit gaande dat Blad3 het derde blad is.
ADDRESS
CELL() geeft het absolute adres van de cel waarnaar verwezen wordt, als tekst. Voorbeelden:
CEL("ADDRESS"; D2) geeft $D$2 terug.
CEL("ADDRESS"; Blad3.D2) geeft $Blad3.$D$2 terug.
CEL("ADDRESS";'X:\dr\test.ods'#$Blad1.D2) geeft 'file:///X:/dr/test.ods'#$Blad1.$D$2.
FILENAME
CEL() geeft de bestandsnaam en het bladnummer van de cel waarnaar verwezen wordt, als tekst. Voorbeelden:
CEL("FILENAME";D2) geeft 'file:///X:/dr/myfile.ods'#$Blad1 terug, als het hidige document X:\dr\myfile.ods is en de formule op Blad1 staat.
CEL("FILENAME";'X:\dr\myfile.ods'#$Blad1.D2) geeft 'file:///X:/dr/myfile.ods'#$Blad1 terug.
COORD
CEL() geeft het complete celadres in Lotus(TM)-notatie, als tekst. Voorbeelden:
CEL("COORD"; D2) geeft $A:$D$2 terug.
CEL("COORD"; Blad3.D2) geeft $C:$D$2 terug.
CONTENTS
CEL() geeft de inhoud van de cel waarnaar verwezen wordt, zonder enige opmaak. Voorbeeld:
CEL("CONTENTS"; D2) geeft de inhoud van cel D2 (of 0 als D2 leeg is).
TYPE
CEL() geeft tekst terug die het type van de celinhoud aangeeft:
b (blanco) geeft een lege cel aan
l (label) geeft tekst aan, of het resultaat van een formule als tekst
v (waarde) geeft een getal aan, of het resultaat van een formule als een getal
WIDTH
CEL() geeft de breedte van de kolom waarnaar verwezen wordt. De eenheid is het aantal nullen (0) die in de kolom passen in de standaard tekst en de standaard grootte.
PREFIX
CEL() geeft tekst terug die de uitlijning aangeeft van de cel waarnaar verwezen wordt, als:
' = links uitlijnen of links-uitgevuld
" = rechts uitlijnen
^ = gecentreerd
\ = herhalend (momenteel niet actief)
PROTECT
CEL() geeft de status terug van de celbeveiliging voor de cel.
1 = cel is beveiligd
0 = cel is niet beveiligd
FORMAT
CEL() geeft tekst terug die de getalopmaak aangeeft:
, = getal met duizendtal scheidingsteken
F = getal zonder duizendtal scheidingsteken
C = valutaopmaak
S = exponentiële representatie, bijvoorbeeld 1.234+E56
P = percentage
In de hierboven genoemde opmaken, wordt het aantal plaatsen achter de komma opgegeven als een getal. Bijvoorbeeld: de getalopmaak #,##0,0 geeft ,1 terug en de getalopmaak 00,000% geeft P3 terug
D1 = MMM-D-JJ, MM-D-JJ en soortgelijke opmaken
D2 = DD-MM
D3 = MM-JJ
D4 = DD-MM-JJJJ UU:MM:SS
D5 = MM-DD
D6 = UU:MM:SS AM/PM
D7 = UU:MM AM/PM
D8 = UU:MM:SS
D9 = UU:MM
G = Alle andere opmaken
- (Minus) aan het einde = negatieve getallen worden in kleur opgemaakt
() (haakjes) aan het einde = er staat een haakje openen in de opmaakcode
COLOR
CEL() geeft 1 terug als negatieve waarden zijn opgemaakt in kleur, anders 0.
PARENTHESES
CEL() geeft 1 terug als de opmaakcode een haakje openen bevat (, anders 0.


Problemen:

  • CEL() geeft informatie terug die werd gevonden toen de doelcel voor het laatst werd bijgewerkt. Bijvoorbeeld: CEL("WIDTH"; D2) geeft de breedte van kolom D terug - maar als kolom D dan breder is gemaakt, zal de teruggegeven waarde niet worden bijgewerkt totdat de inhoud van D2 wordt gewijzigd. Gebruik (bijvoorbeeld) CEL("WIDTH"; D2) + 0*ASELECT(); dit werkt omdat ASELECT() bijwerkt als de kolombreedte wordt gewijzigd, om er voor te zorgen dat er wordt bijgewerkt.

Zie ook

Personal tools