Rijen en kolommen

From Apache OpenOffice Wiki
< NL‎ | Documentation‎ | BASIC Guide
Revision as of 14:04, 7 July 2018 by Sancho (Talk | contribs)

(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
Jump to: navigation, search
Book.png


Elk blad bevat een lijst van zijn rijen en kolommen. Deze zijn beschikbaar via de eigenschappen Rows en Columns van het object werkbladdocument en ondersteunen de services com.sun.star.table.TableColumns en/of com.sun.star.table.TableRows.

Het volgende voorbeeld maakt twee objecten die verwijzen naar de eerste kolom en de eerste rij van een blad en slaan de verwijzingen op in de objectvariabelen EersteKolom en EersteRij.

Dim Doc As Object
Dim Blad As Object
Dim EersteRij As Object
Dim EersteKolom As Object
 
Doc = ThisComponent
Blad = Doc.Sheets(0)
 
EersteKolom = Blad.Columns(0)
EersteRij = Blad.Rows(0)

De objecten Kolom ondersteunen de service com.sun.star.table.TableColumn die de volgende eigenschappen heeft:

Width (long)
breedte van een kolom in 100-en van een millimeter.
OptimalWidth (Boolean)
stelt een kolom in op zijn optimale breedte.
IsVisible (Boolean)
maakt een kolom zichtbaar.
IsStartOfNewPage (Boolean)
maakt, bij afdrukken, een pagina-einde vóór een kolom.

De breedte van een kolom wordt alleen geoptimaliseerd als de eigenschap OptimalWidth is ingesteld op True. Als de breedte van een individuele cel wordt veranderd, wordt de breedte van de kolom waarin die cel is opgenomen, niet veranderd. In termen van functionaliteit is OptimalWidth meer een methode dan een eigenschap.

De objecten Rij zijn gebaseerd op de service com.sun.star.table.TableRow die de volgende eigenschappen heeft:

Height (long)
hoogte van de rij in 100-en van een millimeter.
OptimalHeight (Boolean)
stelt de rij in op zijn optimale hoogte.
IsVisible (Boolean)
maakt de rij zichtbaar.
IsStartOfNewPage (Boolean)
maakt, bij afdrukken, een pagina-einde vóór de rij.

Als de eigenschap OptimalHeight van een rij is ingesteld op True, verandert de rijhoogte automatisch als de hoogte van de rij wordt veranderd. Automatische optimalisatie gaat door totdat de rij een absolute hoogte krijgt toegewezen via de eigenschap Height.

Het volgende voorbeeld activeert de automatische hoogte-optimalisatie voor de eerste vijf rijen in het blad en maakt de tweede kolom onzichtbaar.

Dim Doc As Object
Dim Blad As Object
Dim Rij As Object
Dim Kolom As Object
Dim I As Integer
 
Doc = ThisComponent
Blad = Doc.Sheets(0)
 
For I = 0 To 4
   Rij = Blad.Rows(I)
   Rij.OptimalHeight = True
Next I
 
Kolom = Blad.Columns(1)
Kolom.IsVisible = False
Documentation note.png De lijsten Rows en Columns kunnen worden benaderd door een index in Apache OpenOffice BASIC. De echte aanroep voor de API is: Blad.getColumns.getByIndex(1)
Documentation note.png VBA : Anders dan in VBA heeft de eerste kolom de index 0 en niet de index 1.


Rijen en kolommen invoegen en verwijderen

De objecten Rows en Columns van een blad kunnen toegang krijgen tot bestaande rijen en kolommen en ze ook invoegen en verwijderen.

Dim Doc As Object
Dim Blad As Object
Dim NieuweKolom As Object
 
Doc = ThisComponent
Blad = Doc.Sheets(0)
 
Blad.Columns.insertByIndex(3, 1)
Blad.Columns.removeByIndex(5, 1)

Dit voorbeeld gebruikt de methode insertByIndex om een nieuwe kolom in te voegen op de plaats van de vierde kolom in het blad (index 3 - nummering start met 0). De tweede parameter specificeert het aantal kolommen dat ingevoegd moet worden (in dit voorbeeld: één).

De methode removeByIndex verwijdert de zesde kolom (index 5). Wederom: de tweede parameter specificeert het aantal kolommen dat u wilt verwijderen.

De methoden voor invoegen en verwijderen van rijen gebruiken de functie voor het object Rows op dezelfde wijze als de getoonde methode voor het bewerken van kolommen met behulp van het object Columns.


Content on this page is licensed under the Public Documentation License (PDL).
Personal tools