FR/Documentation/Detection de certificat

Dans Windows, OOo utilise des certificats issus du stockage de clé du système.

Sur toutes les autres plateformes , OOo recherche le profil mozilla par défaut.

L'ordre de recherche est :

1) Thunderbird 2) Mozilla 3) Firefox 4) Defaut (Quoique cela veuille dire...)

Malheureusement il n'y a pas d'option pour choisir un autre profil, mais ce chemin peut être désigné avec la variable d'environnement MOZILLA_CERTIFICATE_FOLDER.

Vous pouvez tester cette détection avec ce petit script:

Option Explicit

Sub MozProfile
	Dim oMozBootstrap as Object
	Dim sMsg as String
	Dim sDefault as String

	oMozBootstrap = createUnoService( "com.sun.star.mozilla.MozillaBootstrap" )
	
	sMsg = "Détection du profil Mozilla par OpenOffice.org" + Chr$(10) + Chr$(10)
	CheckMozProfile( oMozBootstrap, "Thunderbird", com.sun.star.mozilla.MozillaProductType.Thunderbird, sMsg, sDefault )
	sMsg = sMsg + Chr$(10)
	CheckMozProfile( oMozBootstrap, "Mozilla", com.sun.star.mozilla.MozillaProductType.Mozilla, sMsg, sDefault )
	sMsg = sMsg + Chr$(10)
	CheckMozProfile( oMozBootstrap, "Firefox", com.sun.star.mozilla.MozillaProductType.Firefox, sMsg, sDefault )
	sMsg = sMsg + Chr$(10)
	CheckMozProfile( oMozBootstrap, "Default", com.sun.star.mozilla.MozillaProductType.Default, sMsg, sDefault )
	sMsg = sMsg + Chr$(10)
	sMsg = sMsg + "Le premier chemin détecté sera celui utilisé pour les certificats:" + Chr$(10)
	if Len( sDefault ) > 0 Then
		sMsg = sMsg + sDefault
	else
		sMsg = sMsg + "Pas de profil trouvé !"
	end if
	sMsg = sMsg + Chr$(10) + Chr$(10) + "Vous pouvez désigner le bon chemin par la variable d'environnement MOZILLA_CERTIFICATE_FOLDER" + Chr$(10) + " "
	
	
	MsgBox sMsg,64

End Sub

Sub CheckMozProfile( oMozBootstrap, TypeName, TypeID, sMsg, sDefault )
	Dim sProfile as String
	Dim sPath as String

	sMsg = sMsg + TypeName + ":" + Chr$(10) + "Nom du profil: "
	sProfile = 	oMozBootstrap.getDefaultProfile(TypeID)
	if Len( sProfile ) > 0 Then
		sMsg = sMsg + sProfile
		sPath = oMozBootstrap.getProfilePath(TypeID, sProfile )
		sMsg = sMsg + Chr$(10) + "Profile path: " + sPath + Chr$(10)
		if Len( sDefault ) = 0 Then
			sDefault = sPath
		end if
		
	else
		sMsg = sMsg + "PAS TROUVE" + Chr$(10)
	endif
End Sub

Lancer ce code vous donnera toutes les informations dont vous aurez besoin pour modifier la variable d'environnement MOZILLA_CERTIFICATE_FOLDER.

Si vous choississez Firefox lancez :

export MOZILLA_CERTIFICATE_FOLDER=~/.mozilla/firefox/u1f6p56r.default

Avant de demarrer OOo ou modifiez le fichier office.sh.

See also

• Comment utiliser une signature numerique
• Just switch! - Secure document exchange with StarOffice 8
• Digital signatures (SUN-pdf file)