FR/Documentation/Calc: fonction VDB

VDB

Renvoie l'amortissement d'un actif pour une année donnée par la méthode de l'amortissement dégressif à taux variable.

Syntaxe :

VDB(coût;valeur_résiduelle;durée;début_période;fin_période;facteur;non_linéaire)

coût: le coût initial de l'actif.

valeur_résiduelle: est la valeur à la fin de l'amortissement (parfois appelée valeur résiduelle de l'actif).

durée: le nombre d'année pour lequel l'actif est amorti.

début_période, fin_période: les numéros de début et de fin d'année définissant la période pour laquelle l'amortissement est calculé. Cela peut être fractionnel de 0 à durée.

facteur: le facteur pour paramétrer le taux d'amortissement (2 si omis).

non_linéaire: VRAI pour éviter VDB d'utiliser tout amortissement linéaire (FAUX si omis - ie si omis, l'amortissement linéaire sera utilisé lorsque approprié)

Pour calculer l'amortissement, VDB utilise un taux fixe. Quand facteur = 2 c'est la méthode d'amortissement dégressif à taux variable (parce que c'est le double du taux linéaire qui va déprécier l'actif à zéro. Le taux est donné par :

taux = facteur / durée.

L'amortissement chaque année est calculé à la fin de l'année comme :

valeur_début_année * taux.

Cependant si l'amortissement linéaire à la valeur_résiduelle est supérieur à cela, il est utilisé à la place. L'amortissement linéaire à la valeur_résiduelle pour l'année est donné par :

(valeur_début_année - valeur_résiduelle) / année_durée_restante.

Pour empêcher la valeur de tomber en-dessous de valeur_résiduelle, l'amortissement de toutes les années est limité à :

valeur_début_année - valeur_résiduelle.

Cela définit la valeur à la fin de chaque année. VDB renvoie l'amortissement pour la période début_période à fin_période. 0 est le début de la vie de l'actif et durée la fin. Ainsi la période 0 à 2 returns the depreciation in the first two years of the asset's life. The depreciation is calculated as the book value at début_période laisse la valeur à fin_période.

Les fractions sont permises : la période 1,25 à 3,5 renvoie l'amortissement de fin du premier trimestre dans la seconde année à la fin du second trimestre dans la quatrième année. La valeur pour une période fractionnelle est trouvée par interpolation linéaire à partir des valeurs de fin d'année.

Le chiffre de l'amortissement renvoyé est toujours arrondi à deux décimales.

Exemple :

VDB(100000;5000;10;0;1)

renvoie 20000 en unités monétaires, l'amortissement lors de la première année - c'est à dire 100000 * 2 / 10 (méthode d'amortissement dégressif à taux variable).

VDB(100000;5000;10;0;2)

renvoie 36000 en unités monétaires, l'amortissement lors des deux premières années - c'est à dire 20000 dans la première année plus 80000 * 2 / 10 (méthode d'amortissement dégressif à taux variable).

VDB(100000;5000;10;1,5;2,5)

renvoie 14400 en unités monétaires, l'amortissement de la mi-temps de la seconde année à la mi-temps de la troisième année. La valeur pour période = 1 est 80000 et pour période = 2 est 64000. En utilisant une interpolation linéaire, la valeur pour période = 1.5 est 64000 + (80000-64000) * 0,5 = 72000 ; de façon similaire, la valeur pour période = 2.5 est 57600. L'amortissement renvoyé est la différence entre ces valeurs, i.e. 72000 - 57600 = 14400.

VDB(100000;5000;10;7;8)

renvoie 5303,60 en unités monétaires, l'amortissement la 8è année. La valeur au début de la 8è année est 20910,80 (100000 - VDB(100000;5000;10;0;7)). L'amortissement linéaire (ligne bleue) est (20910,80 - 5000)/3 = 5303,60, qui est supérieur à l'amortissement dégressif à taux variable (ligne rouge ; il est au-dessus de la ligne bleue parce que l'amortissement est inférieur).

VDB(100000;5000;10;9;10)

renvoie 5303,60 en unités monétaires, comme ci-dessus, l'amortissement linéaire est constant.

VDB(100000;5000;10;0;10;2;VRAI)

renvoie 89262,58 en unités monétaires. Avec l'amortissement linéaire désactivé l'amortissement total pendant la durée de vie tombe près des 95000 requis pour réduire la valeur à 5000 (ligne rouge).

VDB(100000;20000;10;0;1)

renvoie 20000 en unités monétaire, l'amortissement lors de la première année - c'est à dire 100000 * 2 / 10 (amortissement à taux dégressif double).

VDB(100000; 20000;10;7;8)

renvoie 971,52 en unités monétaires, un amortissement suffisant pour limiter la valeur à la valeur_résiduelle (ligne bleue).

VDB(100000; 20000; 10; 8; 10)

renvoie 0 en unités monétaires ; aucun amortissement n'est possible.

Voir également :

DB, DDB, AMORLIN, SYD

Fonctions financières

Fonctions listées alphabétiquement, Fonctions listées par catégories

Issues :

• Pour suivre la pratique sous Excel, l'arrondi est à deux décimale, mais c'est dommage pour ceux dont l'unité monétaire n'est pas arrondie à deux décimales.
• VDB(100000;20000;10;7,25;7,75) renvoie une valeur erronée sous Excel et sous Calc (différente pour chaque). Cela semble affecter uniquement les périodes fractionnelles dans l'année ou l'amortissement est limité. Voir Issue 91651.

Content on this page is licensed under the Public Documentation License (PDL).