Difference between revisions of "FR/Documentation/Calc: fonction STYLE"

Revision as of 15:23, 30 May 2009

STYLE

Applique un style (par exemple une couleur) à une cellule.

Syntaxe :

STYLE(style; temps_sec; style_final)

STYLE applique le style initial style à sa cellule pour temps_sec secondes et ensuite applique le style final style_final. Chaque style est donné comme texte.

Les styles sont listés (et peuvent être créés) dans la fenêtre Format - Styles et formatage.

Le style initial est appliqué pour temps_sec secondes après la cellule elle-même est recalculée. Notez qu'un recalcul manuel (touche F9 ou Outils - Contenu des cellules - Recalculer) ne rendra pas le style initial.

temps_secs et style_final peuvent être tous deux omis ; style est alors appliqué de façon permanente.

STYLE renvoie la valeur numérique 0, elle peut donc être ajoutée à un calcul existant dans la cellule sans en modifier le résultat. Voir les exemples ci-dessous.

Une autre façon d'appliquer des styles peut être d'utiliser Format - Formatage conditionnel....

Il n'y a pas de façon directe de déterminer (dans une formule) quel formatage a été appliqué à une cellule.

Exemple :

Dans ces exemples, il est supposé que vous avez créé un nouveau style "Rouge" où la cellule a un arrière-plan rouge. "Standard" est le style par défaut déjà défini dans Calc.

=3 + 5 + STYLE("Rouge"; 3; "Standard")

affiche 8 (le résultat de l'addition de 3 et 5) avec un arrière-plan de 3 secondes, et avec le style standard ensuite.

=RACINE(9) + STYLE("Rouge")

affiche 3 (la racine carrée de 9) de façon permanente avec un arrière-plan rouge.

=A1 + STYLE(SI(A1>3;"Rouge";"Standard"))

affiche le contenu numérique de la cellule A1 avec un arrière-plan rouge si A1 est supérieure à 3. Ici, la fonction SI renvoie le nom du style de façon à ce que STYLE soit utilisée (aussi bien "Rouge" ou "Standard"), en fonction de la valeur de la cellule A1.

=A1 + STYLE(SI(ACTUELLE()>3;"Rouge";"Standard"))

affiche également le contenu numérique de la cellule A1 avec un arrière-plan rouge si A1 est supérieure à 3.

="Du texte" & T(STYLE("Rouge"))

affiche le texte Du texte avec un arrière-plan rouge. La fonction STYLE renvoie toujours 0, donc T(0) renverra une chaîne de taille zéro qui peut être concaténée avec une châine existante dans l'affecter.

=SI(STYLE("Rouge"); ""; votre_formule)

où votre_formule représente une formule, affiche le résultat de votre_formule avec un arrière-plan rouge. Cette méthode peut être utile si vous ne pouvez savoir si votre_formule va retourner du texte ou un nombre (par exemple avec RECHERCHEH).

Voir également :

RACINE, ACTUELLE, T

Fonctions classeur,

Fonctions listées alphabétiquement, Fonctions listées par catégories

Issues :

La fonction STYLE est unique à Calc