Difference between revisions of "FR/Documentation/Calc: fonction RECHERCHEH"

From Apache OpenOffice Wiki
Jump to: navigation, search
m (Voir également :)
m (Issues :)
Line 86: Line 86:
  
 
=== Issues : ===
 
=== Issues : ===
*La sensibilité à la casse est discuté sur l'[http://qa.openoffice.org/issues/show_bug.cgi?id=71000 issue 71000]
+
*La sensibilité à la casse est discutée sur l'[http://qa.openoffice.org/issues/show_bug.cgi?id=71000 issue 71000]

Revision as of 14:33, 26 October 2008


RECHERCHEH

Renvoie une valeur à partir d'une ligne de table, dans la ligne trouvée par la recherche dans la première colonne.

Syntaxe :

RECHERCHEH(valeur_recherchée; table; index_ligne; mode)

valeur_recherchée est une valeur (nombre, texte ou valeur logique) à rechercher dans la ligne supérieure de la plage/matrice table. Lorsqu'une valeur correspond dans la ligne supérieure, RECHERCHEH renvoie la valeur correspondante (dans la même colonne) dans la ligne index_ligneème de table, où index_ligne = 1 est la ligne supérieure.
Si mode est 0 ou FAUX, la ligne supérieure de la table peut être non ordonnée et la première correspondance exacte est trouvée (en cherchant de gauche à droite).
Si mode est 1 ou VRAI, ou est omis, la ligne supérieure de la table doit être triée, avec les nombres en ordre ascendants apparaissant avant les valeurs de texte en ordre alphabétique. RECHERCHEH décide où, dans la ligne supérieure, valeur_recherchée devrait apparaître. S'il y a une correspondance exacte, c'est la colonne trouvée ; s'il y a plus d'une correspondance exacte, la colonne trouvée n'est pas nécessairement la plus à gauche. S'il n'y a pas de correspondance exacte, la colonne à la gauche d'où la valeur pourrait apparaître dans la ligne supérieure est trouvée ; une erreur #N/A est renvoyée si cette colonne n'est pas dans la table.


Si les expressions régulières sont activées dans la boîte de dialogue Outils - Options - OpenOffice.org Calc - Calcul, RECHERCHEH trouvera les correspondances exactes en traitant la valeur_recherchée comme une expression régulière. Cela n'a de sens et ne doit être utilisé que si mode est 0 ou FAUX.
Si 'Critères de recherche = et <> doivent correspondre à des lignes entières' est activé sous Outils - Options - OpenOffice.org Calc - Calcul, valeur_recherchée doit correspondre au texte complet dans la cellule ; sinon, c'est juste une partie du texte qui correspond.
La correspondance est toujours insensible à la casse - Le paramètre de casse dans la boîte de dialogue Outils - Options - OpenOffice.org Calc - Calcul ne s'applique pas.

Exemples:

Dans ces exemples, les cellules A1, B1, C1, D1, E1 contiennent 3, 5, chat, mat, matter, et les cellules A2, B2, C2, D2, E2 contiennent A, B, C, D, E.

Calc hlookup example.png

RECHERCHEH(3; A1:E2; 2; 0)

renvoie A. La cellule A1 dans la ligne supérieure correspond à 3. Le contenu de la cellule correspondante dans la 2ème ligne (c'est à dire A2) est renvoyé. La ligne supérieure est triée, mais ce n'est pas nécessaire en mode 0.

RECHERCHEH(4; A1:E2; 2; 0)

renvoie #N/A. Il n'y a pas de correspondance pour 4.

RECHERCHEH("CHAT"; A1:E2; 2; 0)

renvoie C. La différence entre les minuscules et majuscules est ignorée, donc CHAT correspond à chat.

RECHERCHEH("ch.t"; A1:E2; 2; 0)

renvoie C si les expressions régulières sont activées (et #N/A sinon). Le point '.' signifie 'n'importe quel caractère unique' dans une expression régulière donc ch.t correspond à chat.

RECHERCHEH(".at"; A1:E2; 2; 0)

renvoie C si les expressions régulières sont activées. chat correspond; tout comme mat, mais la correspondance la plus à gauche est toujours trouvée en 0.

RECHERCHEH("at"; A1:E2; 2; 0)

renvoie #N/A si 'Critères de recherche = et <> doivent correspondre à des lignes entières' est activé et C sinon. at ne correspond à aucun contenu complet de cellule mais correspond à une partie de chat.

RECHERCHEH(3; A1:E2; 2; 1)

renvoie A. La cellule A1 dans la ligne supérieure correspond à 3. La ligne supérieure doit être triée en mode 1, avec le texte venant après les nombres. matter suit mat parce que même si les premières lettres sont les mêmes, matter contient plus de lettres.

RECHERCHEH(4; A1:E2; 2; 1)

renvoie A. 4 devrait apparaître entre 3 et 5 dans la ligne supérieure, de façon à ce que la position à gauche soit trouvée.

RECHERCHEH(1; A1:E2; 2; 1)

renvoie #N/A. 1 devrait apparaître avant 3 dans la ligne supérieure et il n'y a pas de position à gauche de ça dans la table.

RECHERCHEH(7; A1:E2; 2; 1)

renvoie B. 7 devrait apparaître entre 5 et chat dans la ligne supérieure, de façon à ce que la position à gauche soit trouvée.

RECHERCHEH("abricot"; A1:E2; 2; 1)

renvoie B. abricot devrait apparaître entre 5 et chat dans la ligne supérieure, de façon à ce que la position à gauche soit trouvée.

RECHERCHEH("mate"; A1:E2; 2; 1)

renvoie D. mate devrait apparaître entre mat et matter dans la ligne supérieure, de façon à ce que la position à gauche soit trouvée.

RECHERCHEH("rat"; A1:E2; 2; 1)

renvoie E. rat devrait apparaître après matter dans la ligne supérieure, de façon à ce que la position à gauche soit trouvée.

RECHERCHEH("at"; A1:E2; 2; 1)

renvoie B, même si 'Critères de recherche = et <> doivent correspondre à des lignes entières' est désactivé. Dans le cas où la correspondance entre at et chat est ignorée en faveur du traitement de at comme un mot venant entre 5 et chat.

Voir également :

CHOISIR, INDEX, RECHERCHE, EQUIV, DECALER, RECHERCHEV

PROBABILITE

Expressions régulières dans Calc

Fonctions classeur

Fonctions listées alphabétiquement, Fonctions listées par catégories

Issues :

  • La sensibilité à la casse est discutée sur l'issue 71000
Personal tools