FR/Documentation/Calc:Fonction NB.SI

NB.SI

compte le nombre de cellules d'une plage, qui vérifient une condition spécifique.

Syntaxe :

NB.SI(plage_test; condition)

Cette fonction compte les cellules de la plage test_range qui vérifient la condition.

condition est, ou fait référence à, une chaîne de caractères présentant le format suivant :

comparateur valeur où

comparateur correspond à l'un des opérateurs mathématiques suivants : >, <, >=, <=, =, <> (par défaut, si comparateur est omis, = est sous-entendu), et

valeur est la valeur (nombre ou texte) de comparaison.

Par exemple, la condition “>4” vérifie si le contenu de la cellule est supérieur à 4.

Cette fonction est très puissante pour comparer des textes, afin de déterminer leur similitude ou leur différence (= ou <>), mais une utilisation optimale ne peut être obtenue qu'au prix de quelques précautions préalables. Il est en particulier nécessaire de déterminer le comportement attendu dans le menu Outils – Options - OpenOffice.org Calc - Calcul:

Si l'option Critères de recherche = et <> doivent correspondre à des lignes entières est cochée, alors la condition “rouge” ne sera vérifiée que pour une cellule contenant exactement rouge; mais si elle est décochée, alors elle sera vérifiée pour des cellule contenant rouge, rougeole, rouge sang.

Si l'option Autoriser les caractères génériques dans les formules est cochée, la condition sera vérifiée en utilisant des Caractères génériques dans Calc (lien en anglais) – ainsi, par exemple "ro.ge" sera vérifiée pour rouge et ronge, alors que "rouge.*" sera vérifiée pour rouge, rouges, rougeur, rougeole ou rouge-gorge (en revanche, elle ne sera pas vérifiée pour becs rouges parce que dans ce cas, le mot rouge n'est pas situé en début de cellule ; pour qu'une cellule contenant becs rouges vérifie aussi la condition, il faudrait que la condition soit rédigée de la façon suivante : .*rouge.*).

Pour l'heure, le choix de cocher ou non l'option Respecter la casse est sans effet (la casse est toujours ignorée) – ce comportement est cependant susceptible de changer dans les versions futures de OOo et il convient donc de ne pas se reposer sur ce comportement actuel.

Les cellules vides inclues dans la plage plage_test sont ignorées (elles ne vérifient jamais la condition).

condition ne peut comporter qu'une condition unique. Voir Sommes et calculs conditionnels dans Calc pour de plus amples informations.

Exemple :

NB.SI(C2:C8; ">=20")

retourne le nombre de cellules dans la plage C2:C8 dont le contenu est numériquement supérieur ou égal à 20.

NB.SI(C2:C8; F1)

où F1 contient le texte >=20 retourne le même résultat que ci-dessus.

NB.SI(C2:C8; "<"&F2)

où F2 contient 20 retourne le nombre de cellules dans la plage C2:C8 dont le contenu est numériquement inférieur à 20.

NB.SI(A2:A8; ">=P")

retourne le nombre de cellules dans la plage A2:A8 dont le contenu débute avec la lettre P ou une lettre venant après P dans l'alphabet.

NB.SI(B2:B8; "rouge")

retourne le nombre de cellules dans la plage B2:B8 contenant rouge, mais ce nombre dépend des options mentionnées comme mentionné ci-dessus).

Voir également :

fonction SOMME.SI, fonction NB, fonction NBVAL, fonction NB.VIDE

Sommes et calculs conditionnels dans Calc

Caractères génériques dans Calc (lien en anglais)